cvsp_p.f

Go to the documentation of this file.

!                       *****************
                        SUBROUTINE cvsp_p
!                       *****************
!
     &(path_pre,file_pre,jg)
!
!***********************************************************************
! SISYPHE   V7P2                                   16/05/2017
!***********************************************************************
!
!brief   CSV-FILE OUTPUT OF A VERTICAL SORTING PROFILE IN POINT J
!
!history UWE MERKEL
!+        20/07/2011
!+        V6P3
!+
!
!history  P. A. TASSI (EDF R&D, LNHE)
!+        12/03/2013
!+        V6P3
!+   Cleaning, cosmetic
!
!history  J-M HERVOUET (EDF R&D, LNHE)
!+        02/01/2014
!+        V7P0
!+   Use of KNOGL replaced by GLOBAL_TO_LOCAL_POINT.
!
!history UWE MERKEL, R. KOPMANN (BAW)
!+        2016 / 2017
!+        V6P3 / V7P2
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!| JG             |<--| GLOBAL POINT NUMBER
!| PATH_PRE       |<--| WHERE TO SAVE
!| FILE_PRE       |<--| FILENAMETRUNK
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      USE declarations_sisyphe
      USE bief
      USE bief_def
      USE cvsp_outputfiles
!
      USE declarations_special
      IMPLICIT NONE
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER     , INTENT(IN)  :: JG
      CHARACTER(*), INTENT(IN) :: PATH_PRE
      CHARACTER(*), INTENT(IN) :: FILE_PRE
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      CHARACTER(LEN=100) DEBUGFILE
      CHARACTER(LEN=7) OCSTR
      INTEGER I, K, J
      DOUBLE PRECISION AT, BSUM
      INTEGER :: ID
!
!-----------------------------------------------------------------------
!
      at = dt*lt/percou
      j = jg
      outputcounter = outputcounter + 1
!
!     GLOBAL NUMBERS TO LOCAL NUMBERS
!
      IF(ncsize.GT.1) THEN
        j = global_to_local_point(jg,mesh)
      ENDIF
!
      WRITE(unit=ocstr, fmt='(I7)') outputcounter
      DO i=1,7
        IF(ocstr(i:i)==' ') ocstr(i:i)='0'
      ENDDO
!
      WRITE(unit=debugfile, fmt='(A,A,A,A,I8,A,G15.8,A)')
     &     path_pre,ocstr,'_',file_pre,
     &     jg,'_T_',at,'_VSP.CSV'

      DO i=1,len_trim(debugfile)
        IF(debugfile(i:i)==' ') debugfile(i:i)='_'
      ENDDO
!
      IF(j > 0) THEN
        CALL get_free_id(id)
        OPEN(id, file=debugfile, status='UNKNOWN' )
        rewind id
        WRITE(id,*)
     &"J K FD50(I) AT PRO_D(K_I) PRO_F(K_I) X Y D50 ALT TOB HEIGHT"
!
        DO k=1,pro_max(j)
          bsum = 0.d0
          DO i=1,nsicla
            bsum = fdm(i)*pro_f(j,pro_max(j)+1-k,i) + bsum
          ENDDO
!
          DO i=1,nsicla
            IF(k.EQ.1) THEN
! FULL OUTPUT WITH COORDINATES ETC. ON SURFACE
              WRITE (id,'(I8,1X,I4,1X,10(G20.12,1X))')
     &              jg,pro_max(j)+1-k,fdm(i),at,
     &              pro_d(j,pro_max(j)+1-k,i),
     &              pro_f(j,pro_max(j)+1-k,i),x(j),y(j),
     &              bsum,es(j,1),tob%R(j), z%R(j)
            ELSE
! FOLLOWING SECTIONS
              WRITE (id,'(I8,1X,I4,1X,5(G20.12,1X))')
     &              jg,pro_max(j)+1-k,fdm(i),at,
     &              pro_d(j,pro_max(j)+1-k,i),
     &              pro_f(j,pro_max(j)+1-k,i)
            ENDIF
          ENDDO
        ENDDO
!
        bsum = 0.d0
        DO i=1,nsicla
          bsum = fdm(i)*pro_f(j,1,i) + bsum
        ENDDO
!
        CLOSE(id)
!
      ENDIF
!
!-----------------------------------------------------------------------
!
      RETURN
      END SUBROUTINE cvsp_p