cvsp_init_from_layers.f

Go to the documentation of this file.

!                   ********************************
                    SUBROUTINE cvsp_init_from_layers
!                   ********************************
!
!
!***********************************************************************
! SISYPHE V6P3                                   14/03/2013
!***********************************************************************
!
!brief   INITS A VERTICAL SORTING PROFILE USING HIRANO LAYERS
!
!history UWE MERKEL
!+        19/04/2012
!+        V6P2
!+
!
!history  P. A. TASSI (EDF R&D, LNHE)
!+        12/03/2013
!+        V6P3
!+   Cleaning, cosmetic
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!|           |---|
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      USE declarations_telemac
      USE declarations_sisyphe
!
      IMPLICIT NONE
!
      INTEGER  I, J, M, L
      DOUBLE PRECISION DEPTH
!
!-----------------------------------------------------------------------
!
      ALLOCATE(pro_d(npoin,pro_max_max,nsicla))
      ALLOCATE(pro_f(npoin,pro_max_max,nsicla))
      ALLOCATE(pro_max(npoin))
!
!-----------------------------------------------------------------------
!
      DO j=1,npoin
        depth = 0                    ! INIT DEPTH OF THE VSP
        pro_max(j) =  2* nlayer%I(j) ! 2 SECTION POINTS PER LAYER
        l = pro_max(j)
!
!-----------------------------------------------------------------------
! WATER / BOTTOM
!-----------------------------------------------------------------------
!
        DO i=1,nsicla
          pro_d(j,l,i) = zf%R(j)
          pro_f(j,l,i) = avail(j,1,i)
        ENDDO
!
!-----------------------------------------------------------------------
! SECTIONS
!-----------------------------------------------------------------------
!
        DO m=1,nlayer%I(j)-1   !FOR THE UPPER 8 LAYERS
          depth = depth + es(j,m)
          l = l - 1
          DO i=1,nsicla
            pro_d(j,l,i) = zf%R(j) - depth
            pro_f(j,l,i) = avail(j,m,i)
          ENDDO
          l = l - 1
          DO i=1,nsicla
            pro_d(j,l,i) = zf%R(j) - depth
            pro_f(j,l,i) = avail(j,m+1,i)
          ENDDO
        ENDDO
!
!-----------------------------------------------------------------------
! BOTTOM / RIGID BED
!-----------------------------------------------------------------------
!
        l = l - 1
        DO i=1,nsicla
          pro_d(j,l,i) = zr%R(j)
          pro_f(j,l,i) = avail(j,nlayer%I(j),i)
        ENDDO
!
        CALL cvsp_compress_dp(j,1.d-5)
!
      ENDDO
!
!-----------------------------------------------------------------------
!
      RETURN
      END SUBROUTINE cvsp_init_from_layers