crsl11.f

Go to the documentation of this file.

!                   *****************
                    SUBROUTINE crsl11
!                   *****************
!
     &(newsl,oldsl,zf,ikle,nelem,nelmax)
!
!***********************************************************************
! BIEF   V6P1                                   21/08/2010
!***********************************************************************
!
!brief    CORRECTS THE FREE SURFACE COMPUTATION BY ELEMENTS
!+                TO TAKE ACCOUNT OF THE TIDAL FLATS.
!
!history  J-M JANIN    (LNH)
!+        27/11/92
!+        V5P5
!+
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        13/07/2010
!+        V6P0
!+   Translation of French comments within the FORTRAN sources into
!+   English comments
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        21/08/2010
!+        V6P0
!+   Creation of DOXYGEN tags for automated documentation and
!+   cross-referencing of the FORTRAN sources
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!| IKLE           |-->| CONNECTIVITY TABLE
!| NELEM          |-->| NUMBER OF ELEMENTS
!| NELMAX         |-->| MAXIMUM NUMBER OF ELEMENTS
!| NEWSL          |<->| MODIFIED FREE SURFACE, PER ELEMENT
!| OLDSL          |-->| REAL FREE SURFACE, PER POINT
!| ZF             |-->| BATHYMETRY
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      USE declarations_special
      IMPLICIT NONE
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER, INTENT(IN)             :: NELEM,NELMAX
      DOUBLE PRECISION, INTENT(INOUT) :: NEWSL(nelmax,3)
      DOUBLE PRECISION, INTENT(IN)    :: OLDSL(*),ZF(*)
      INTEGER, INTENT(IN)             :: IKLE(nelmax,3)
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER IELEM,IK(3),J(3)
!
!-----------------------------------------------------------------------
!
      INTRINSIC max
!
!-----------------------------------------------------------------------
!
!  1) SORTS (ASCENDING ORDER) THE BOTTOM ELEVATIONS AND POTENTIALLY
!     CORRECTS THE FREE SURFACE ELEVATION FOR DRYING ELEMENTS
!
!-----------------------------------------------------------------------
!
      DO ielem = 1 , nelem
!
        ik(1) = ikle(ielem,1)
        ik(2) = ikle(ielem,2)
        ik(3) = ikle(ielem,3)
        j(1) = 1
        j(2) = 2
        j(3) = 3
!
!       SORTS THE 3 POINTS
!
        IF(zf(ik(2)).LT.zf(ik(1)))  THEN
          j(2)=1
          j(1)=2
        ENDIF
        IF(zf(ik(3)).LT.zf(ik(j(2)))) THEN
          j(3)=j(2)
          j(2)=3
          IF(zf(ik(3)).LT.zf(ik(j(1)))) THEN
            j(2)=j(1)
            j(1)=3
          ENDIF
        ENDIF
!
!       CORRECTS
!
        newsl(ielem,j(1))=max(zf(ik(j(2))),oldsl(ik(j(1))))
        newsl(ielem,j(2))=oldsl(ik(j(2)))
        newsl(ielem,j(3))=
     &  oldsl(ik(j(3)))-max(0.d0,zf(ik(j(3)))-oldsl(ik(j(2))))
!
      ENDDO ! IELEM
!
!-----------------------------------------------------------------------
!
      RETURN
      END