crosfr.f

Go to the documentation of this file.

!                   *****************
                    SUBROUTINE crosfr
!                   *****************
!
     &(x,y,xr,yr,xmail,ymail,npmax,nbor,kp1bor,nptfr,dm,ok)
!
!***********************************************************************
! BIEF   V6P1                                   21/08/2010
!***********************************************************************
!
!brief    WANT TO INTERPOLATE THE BOTTOM ELEVATION FOR A POINT
!+                WITH COORDINATES X AND Y. A POINT (XR,YR) IS USED
!+                IN THIS INTERPOLATION.
!+
!+            CHECKS HERE THAT THIS POINT IS NOT OUTSIDE OF THE
!+                DOMAIN, I.E. CHECKS THAT THE SEGMENT LINKING (X,Y)
!+                AND (XR,YR) DOES NOT INTERSECT WITH THE DOMAIN
!+                BOUNDARY.
!
!warning  JMH : DOES NOT WORK IN PARALLEL MODE
!
!history  J-M HERVOUET (LNHE)
!+        20/03/08
!+        V5P9
!+
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        13/07/2010
!+        V6P0
!+   Translation of French comments within the FORTRAN sources into
!+   English comments
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        21/08/2010
!+        V6P0
!+   Creation of DOXYGEN tags for automated documentation and
!+   cross-referencing of the FORTRAN sources
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!| DM             |-->| MINIMUM DISTANCE TO THE BOUNDARY
!| KP1BOR         |-->| RANK OF THE NEXT POINT ALONG THE BOUNDARY
!| NBOR           |-->| GLOBAL NUMBER OF BOUNDARY NODES
!| NPMAX          |-->| MAXIMUM NUMBER OF POINTS IN THE MESH
!| NPTFR          |-->| NUMBER OF BOUNDARY NODES
!| OK             |<--| IF YES, NO CROSSING OF BOUNDARY
!|                |   | IF NO, POINT OUTSIDE THE DOMAIN
!| X              |-->| ABSCISSA OF POINT WHERE TO INTERPOLATE
!| Y              |   | ORDINATE OF POINT WHERE TO INTERPOLATE
!| XMAIL          |-->| ABSCISSAE OF POINTS IN THE MESH
!| YMAIL          |-->| ORDINATES OF POINTS IN THE MESH
!| XR             |-->| ABSCISSA OF POINT TO BE USED FOR INTERPOLATION
!| XR,YR          |-->| ORDINATE OF POINT TO BE USED FOR INTERPOLATION
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      USE declarations_special
      IMPLICIT NONE
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      DOUBLE PRECISION, INTENT(IN) :: X,Y,XR,YR,DM
      INTEGER, INTENT(IN)          :: NPTFR,NPMAX
      DOUBLE PRECISION, INTENT(IN) :: XMAIL(npmax),YMAIL(npmax)
      INTEGER, INTENT(IN)          :: NBOR(nptfr),KP1BOR(nptfr)
      LOGICAL, INTENT(INOUT)       :: OK
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER KA
!
      DOUBLE PRECISION DM2,XA,YA,XB,YB,DET,ALFA,BETA,EPS,DISTA2,DISTB2
!
!-----------------------------------------------------------------------
!
!     DOES NOT CONSIDER POINTS TOO CLOSE TO THE BOUNDARY
!     DM     : MINIMUM DISTANCE
      dm2 = dm**2
!
      DO ka=1,nptfr
!
! INTERSECTION OF A BOUNDARY SEGMENT AND THE SEGMENT
! FORMED BY THE POINTS (X,Y) AND (XR,YR)
!
        xa = xmail(nbor(ka))
        ya = ymail(nbor(ka))
        xb = xmail(nbor(kp1bor(ka)))
        yb = ymail(nbor(kp1bor(ka)))
!
        det = (xr-x)*(ya-yb) - (yr-y)*(xa-xb)
!
        IF(abs(det).LT.1.d-6) cycle
!
        alfa = ( (xa-x)*(ya-yb) - (ya-y)*(xa-xb) ) / det
        beta = ( (xr-x)*(ya-y ) - (yr-y)*(xa-x ) ) / det
!
        eps=0.05d0
        IF(alfa.GE.eps.AND.alfa.LE.1.d0-eps.AND.
     &     beta.GE.eps.AND.beta.LE.1.d0-eps) THEN
          ok = .false.
          EXIT
        ENDIF
!
! ALSO ELIMINATES THE POINTS TOO CLOSE TO THE BOUNDARY
!
        dista2 = (xr-xa)**2 + (yr-ya)**2
        distb2 = (xr-xb)**2 + (yr-yb)**2
        IF(dista2.LT.dm2.OR.distb2.LT.dm2) THEN
          ok = .false.
          EXIT
        ENDIF
!
      ENDDO ! KA
!
!-----------------------------------------------------------------------
!
      RETURN
      END