cpstvc.f

Go to the documentation of this file.

!                   *****************
                    SUBROUTINE cpstvc
!                   *****************
!
     &( x , y )
!
!***********************************************************************
! BIEF   V7P1
!***********************************************************************
!
!brief    COPIES A VECTOR STRUCTURE ONTO ANOTHER.
!
!history  J-M HERVOUET (LNH)
!+        01/03/1995
!+        V5P1
!+   First version.
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        13/07/2010
!+        V6P0
!+   Translation of French comments within the FORTRAN sources into
!+   English comments
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        21/08/2010
!+        V6P0
!+   Creation of DOXYGEN tags for automated documentation and
!+   cross-referencing of the FORTRAN sources
!
!history  J-M HERVOUET (LNHE)
!+        22/05/2013
!+        V6P3
!+   STATUS now also considered.
!
!history  J-M HERVOUET (EDF LAB, LNHE)
!+        26/06/2015
!+        V7P1
!+   More accurate messages.
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!| X              |-->| STRUCTURE TO BE COPIED
!| Y              |<--| STRUCTURE THAT RECEIVES X ATTRIBUTES
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      USE bief, ex_cpstvc => cpstvc
!
      USE declarations_special
      IMPLICIT NONE
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      TYPE(bief_obj), INTENT(IN)    :: X
      TYPE(bief_obj), INTENT(INOUT) :: Y
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER SIZEX,SIZEY
!
!-----------------------------------------------------------------------
!  TREATS ONLY VECTORS HERE :
!-----------------------------------------------------------------------
!
      IF(y%TYPE.NE.2.OR.x%TYPE.NE.2) THEN
        WRITE(lu,201) x%NAME,x%TYPE,y%NAME,y%TYPE
 201    FORMAT(1x,'CPSTVC : FORBIDDEN CASE FOR X AND Y:',/,1x,
     &            'X=',a6,' TYPE :',1i6                 ,/,1x,
     &            'Y=',a6,' TYPE :',1i6)
        CALL plante(1)
        stop
      ENDIF
!
      sizex = x%DIM1*x%DIM2
      sizey = y%MAXDIM1*y%MAXDIM2
!
      IF(sizex.GT.sizey) THEN
        WRITE(lu,301) x%NAME,sizex,y%NAME,sizey
 301    FORMAT(1x,'CPSTVC : FORBIDDEN CASE FOR X AND Y:',/,1x,
     &            'X=',a6,' SIZE        :',1i8,/,1x,
     &            'Y=',a6,' MAXIMUM SIZE:',1i8)
        CALL plante(1)
        stop
      ENDIF
!
!     DISCRETISATION
      IF(y%ELM.NE.x%ELM.AND.y%STATUS.EQ.1) THEN
        WRITE(lu,401) x%NAME,y%NAME
401     FORMAT(1x,'CPSTVC : COPY OF ',a6,' FORBIDDEN ON ',a6,
     &  ' BECAUSE ITS STATUS IS 1')
        CALL plante(1)
        stop
      ELSE
        y%ELM = x%ELM
      ENDIF
!     FIRST VECTOR DIMENSION
      y%DIM1 = x%DIM1
!     SECOND VECTOR DIMENSION
      y%DIM2 = x%DIM2
!     CASE OF DISCONTINUOUS VECTORS
      y%DIMDISC = x%DIMDISC
!
!     A VECTOR WITH PREVIOUS STATUS 0 NOW DEFINED ON A MESH
!     IT IS DECLARED AS STATUS 2 (DISCRETISATION THAT CAN BE CHANGED)
!
      IF(y%STATUS.EQ.0.AND.(x%STATUS.EQ.1.OR.x%STATUS.EQ.2)) THEN
        y%STATUS=2
      ENDIF
!
!-----------------------------------------------------------------------
!
      RETURN
      END