cpik13.f

Go to the documentation of this file.

!                   *****************
                    SUBROUTINE cpik13
!                   *****************
!
     &(ikle,iklbor,eltseg,nbor,nelbor,nulone,nelem,nelmax,npoin,nptfr,
     & neleb,nelebx)
!
!***********************************************************************
! BIEF   V7P0                                     28/03/2014
!***********************************************************************
!
!brief    EXTENDS THE CONNECTIVITY TABLE.
!+                CASE OF AN EXTENSION TO QUADRATIC ELEMENTS.
!
!history  J-M HERVOUET (LNH)
!+        20/03/08
!+        V5P9
!+
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        13/07/2010
!+        V6P0
!+   Translation of French comments within the FORTRAN sources into
!+   English comments
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        21/08/2010
!+        V6P0
!+   Creation of DOXYGEN tags for automated documentation and
!+   cross-referencing of the FORTRAN sources
!
!history  J-M HERVOUET (LNHE)
!+        16/05/2012
!+        V6P2
!+   Bug corrected in parallel
!
!history  J-M HERVOUET (EDF LAB, LNHE)
!+        28/03/2014
!+        V7P0
!+   Adapted to new numbering of boundary segments.
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!| ELTSEG         |-->| SEGMENTS NUMBERS IN EVERY ELEMENT
!| IKLBOR         |-->| CONNECTIVITY TABLE OF BOUNDARY ELEMENTS
!| IKLE           |<->| CONNECTIVITY TABLE
!| NBOR           |-->| GLOBAL NUMBERS OF BOUNDARY POINTS
!| NELBOR         |-->| BOUNDARY ELEMENT THAT CONTAINS SEGMENT K
!| NELEB          |-->| NUMBER OF BOUNDARY SEGMENTS
!| NELEBX         |-->| MAXIMUM NUMBER OF BOUNDARY SEGMENTS
!| NULONE         |-->| LOCAL NUMBER OF K IN ELEMENT NELBOR
!| NELEM          |-->| NUMBER OF ELEMENTS
!| NELMAX         |-->| MAXIMUM NUMBER OF ELEMENTS
!| NPOIN          |-->| NUMBER OF POINTS IN THE MESH
!| NPTFR          |-->| NUMBER OF BOUNDARY POINTS
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      USE bief, ONLY : ncsize
!
      USE declarations_special
      IMPLICIT NONE
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER, INTENT(IN)    :: NELEM,NELMAX,NPOIN,NPTFR,NELEB,NELEBX
      INTEGER, INTENT(IN)    :: ELTSEG(nelmax,3)
      INTEGER, INTENT(IN)    :: NELBOR(nelebx),NULONE(nelebx)
      INTEGER, INTENT(INOUT) :: IKLE(nelmax,6),IKLBOR(nelebx,3),NBOR(*)
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER IELEM,K,IELEB
!
!-----------------------------------------------------------------------
!
!     CONNECTIVITY TABLE OF QUADRATIC GLOBAL POINTS
!
      DO ielem = 1 , nelem
!
!       NUMBER=NPOIN+NUMBER OF THE SEGMENT CONTAINING THE POINT
!
        ikle(ielem,4) = npoin + eltseg(ielem,1)
        ikle(ielem,5) = npoin + eltseg(ielem,2)
        ikle(ielem,6) = npoin + eltseg(ielem,3)
!
      ENDDO
!
!-----------------------------------------------------------------------
!
!     CONNECTIVITY TABLE OF QUADRATIC BOUNDARY POINTS
!     GLOBAL NUMBERS OF BOUNDARY QUADRATIC POINTS
!
      DO ieleb=1,neleb
        k=iklbor(ieleb,1)
!       WE DECIDE HERE THE BOUNDARY NUMBERING OF QUADRATIC POINTS
        iklbor(ieleb,3)=k+nptfr
        ielem=nelbor(ieleb)
        nbor(iklbor(ieleb,3))=ikle(ielem,nulone(ieleb)+3)
      ENDDO
!
!-----------------------------------------------------------------------
!
!     SECURITY CHECK IN SCALAR MODE
!
      IF(ncsize.LE.1) THEN
        DO ieleb=1,neleb
          k=iklbor(ieleb,1)
          IF(nbor(iklbor(ieleb,3)).NE.k+npoin) THEN
            WRITE(lu,*) 'CPIK13: PROBLEM OF NUMBERING FOR K=',k
            CALL plante(1)
            stop
          ENDIF
        ENDDO
      ENDIF
!
!-----------------------------------------------------------------------
!
      RETURN
      END