conlit.f

Go to the documentation of this file.

!                   *****************
                    SUBROUTINE conlit
!                   *****************
!
     &(nbor,at)
!
!***********************************************************************
! SISYPHE   V7P3                                   17/03/2017
!***********************************************************************
!
!brief    ALLOWS TO IMPOSE TIME VARYING BOUNDARY CONDITIONS
!+               (CONSTANT VALUES CAN BE DIRECTLY IMPOSED IN CONDIM
!+                INPUT FILE).
!+
!+
!+            ALLOWS TO IMPOSE A SAND TRANSPORT RATE AT SOME
!+                BOUNDARY NODES (QBOR AND LIQBOR). IT IS THEN NECESSARY
!+                TO ALSO IMPOSE LIEBOR = KSORT AT THESE NODES !
!
!history  E. PELTIER; C. LENORMANT; J.-M. HERVOUET
!+        11/09/1995
!+
!+
!
!history  CV
!+        19/06/2008
!+        V5P9
!+   TAKES INTO ACCOUNT CBOR_VASE AND CBOR_SABLE
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        13/07/2010
!+        V6P0
!+   Translation of French comments within the FORTRAN sources into
!+   English comments
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        21/08/2010
!+        V6P0
!+   Creation of DOXYGEN tags for automated documentation and
!+   cross-referencing of the FORTRAN sources
!
!history  P. TASSI & J-M HERVOUET (LNHE)
!+        24/07/2012
!+        V6P2
!+   Dealing with new key-word "prescribed solid discharges"
!
!history  P. TASSI
!+        09/07/2013
!+        V6P3
!+   Correction for multiples boundaries. Thanks to Dougal Clunie
!+   for pointing out this error.
!
!history  R. KOPMANN (BAW)
!+        13/07/2016
!+        V7P2
!+        Integrating liquid boundary file for QS
!
!history  M. SECHER AND P. TASSI (EDF)
!+        17/03/2017
!+        V7P3
!+        Add conditional for liquid boundary file for QS
!
!history  J,RIEHME (ADJOINTWARE)
!+        November 2016
!+        V7P2
!+   Replaced EXTERNAL statements to parallel functions / subroutines
!+   by the INTERFACE_PARALLEL
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!| NBOR           |-->| GLOBAL NUMBER OF BOUNDARY POINT
!| AT             |-->| TEMPS (s)
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      USE bief
      USE declarations_sisyphe
      USE declarations_telemac
!
      USE declarations_special
      USE interface_parallel, ONLY : p_max
      IMPLICIT NONE
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER, INTENT(IN)          :: NBOR(nptfr)
      DOUBLE PRECISION, INTENT(IN) :: AT
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER I,K,IFRLIQ,IRANK
      INTEGER YADEB(maxfro)
!
      DOUBLE PRECISION, EXTERNAL :: CGL
      DOUBLE PRECISION, EXTERNAL :: QGL
!
!-----------------------------------------------------------------------
!
!     INITIALISATION OF YADEB
!
      IF(nfrliq.GE.1) THEN
        DO i=1,nfrliq
          yadeb(i)=0
        ENDDO
      ENDIF
!
!-----------------------------------------------------------------------
!
!     DISTRIBUTING THE (TOTAL) PRESCRIBED EVOLUTION TAKEN IN THE
!     BOUNDARY CONDITIONS FILE WITH RESPECT TO FRACTIONS IN THE
!     FIRST LAYER
!
      IF(nsicla.GT.1) THEN
        DO i=nsicla,1,-1
          DO k=1,nptfr
            ebor%ADR(i)%P%R(k)=avail(nbor(k),1,i)*ebor%ADR(1)%P%R(k)
          ENDDO
        ENDDO
      ENDIF
!
!-----------------------------------------------------------------------
!
      DO  k=1,nptfr
!
        i = nbor(k)
!
!       HERE KADH (WALL WITH NO SLIP CONDITION) IS CHANGED INTO KLOG (WALL)
!
        IF(liebor%I(k).EQ.kadh) THEN
          liebor%I(k)= klog
        ELSEIF(liebor%I(k).EQ.kent) THEN
!         WARNING !!!!!!!!!!!!!!    DYNAMITE !!!!!!!!!
!         FOR COMPATIBILITY OF OLD STUDIES, LIEBOR=KENT SUPERSEDES LIQBOR=KENT
!         IF BOTH ARE GIVEN AS KENT
          liqbor%I(k)= ksort
        ENDIF
!
!       CASES WHERE WE HAVE A PRESCRIBED DISCHARGE
!
        IF(liqbor%I(k).EQ.kent) yadeb(numliq%I(k))=1
!
!       DIRICHLET CONDITIONS
!       EITHER ON EVOLUTION OR ON SOLID DISCHARGE
!
        ! USER FUNCTION
        CALL user_conlit(nbor,at)
!
      ENDDO
!
!     DEALING WITH PRESCRIBED SOLID DISCHARGES
!
      IF(nfrliq.GT.0) THEN
        DO ifrliq=1,nfrliq
          IF(ncsize.GT.1) yadeb(ifrliq)=p_max(yadeb(ifrliq))
          IF(yadeb(ifrliq).EQ.1) THEN
!
!         READING BOUNDARY CONDITION FILE WITH SOLID DISCHARGE
!
            IF(charr) THEN
!           AVOID OVERRIDING WITH SUSPENDED SEDIMENT TRANSPORT
              IF(sis_files(sisliq)%NAME(1:1).NE.' ') THEN
                soldis(ifrliq)=qgl(ifrliq,at)
              ENDIF
            ENDIF

            CALL disimp(soldis(ifrliq),q2bor,numliq%I,ifrliq,nsoldis,
     &                  t5,t1,
!                             MASK OF LIQUID BOUNDARIES DONE IN SISYPHE
     &                  nptfr,mask%R,mesh)
!
            IF(nsicla.GT.1) THEN
              DO i=1,nsicla
                DO k=1,nptfr
                  IF(numliq%I(k).EQ.ifrliq.AND.
     &               liqbor%I(k).EQ.kent) THEN
                    qbor%ADR(i)%P%R(k)=avail(nbor(k),1,i)*t1%R(k)
                  ENDIF
                ENDDO
              ENDDO
            ELSE
              DO k=1,nptfr
                IF(numliq%I(k).EQ.ifrliq.AND.
     &             liqbor%I(k).EQ.kent) THEN
                  qbor%ADR(1)%P%R(k)=t1%R(k)
                ENDIF
              ENDDO
            ENDIF
          ENDIF
        ENDDO
      ENDIF
!
!-----------------------------------------------------------------------
!     LICBOR : BOUNDARY CONDITION FOR SEDIMENT CONCENTRATION
!-----------------------------------------------------------------------
!
      IF(susp) THEN
!
        DO k=1,nptfr
!
!         SO FAR LICBOR=LIEBOR (WITH KADH CHANGED INTO KLOG, SEE ABOVE,
!                               BUT CAN BE CHANGED)
!
          licbor%I(k) = liebor%I(k)
!
!         ENTRANCE : IMPOSED CONCENTRATION
!         -------------------------------
!
!         KSORT MUST BE TREATED ALSO BECAUSE SUBROUTINE DIFFIN
!         MAY CHANGE A KSORT INTO KENT, DEPENDING OF FLOW
!
          ifrliq=numliq%I(k)
          IF(liebor%I(k).EQ.kent.OR.liebor%I(k).EQ.ksort) THEN
            DO i=1,nsicla
              irank=i+(ifrliq-1)*nsicla
              cbor%ADR(i)%P%R(k) = cbor_classe(irank)
            ENDDO
          ENDIF
!
!         READING BOUNDARY CONDITION FILE
!
          IF(licbor%I(k).EQ.kent.AND.
     &                         sis_files(sisliq)%NAME(1:1).NE.' ') THEN
            IF(ifrliq.GT.0) THEN
              DO i=1,nsicla
                cbor%ADR(i)%P%R(k)=cgl(ifrliq,at)/xmvs
              ENDDO
            ENDIF
          ENDIF
!
        ENDDO
!
      ENDIF
!
!-----------------------------------------------------------------------
!
      RETURN
      END