comp_nh_com_seg.f

Go to the documentation of this file.

!                   **************************
                    SUBROUTINE comp_nh_com_seg
!                   **************************
!
     &(eltseg,dim1eltseg,nh_com_seg,dim1nhcom,nb_neighb_seg,
     & nb_neighb_pt_seg,gloseg,dimglo,knolg,npoin)
!
!***********************************************************************
! BIEF   V6P1                                   21/08/2010
!***********************************************************************
!
!brief    COMPLETES THE REAL ADDRESS OF SEGMENTS IN NH_COM_SEG.
!+                SEE PARINI WHERE NH_COM_SEG IS INITIALISED AT -999999
!+                AND THEN FILLED WITH 4*IELEM+IFACE TO STORE IELEM AND
!+                IFACE.
!+
!+            THEN THE ADDRESSES ARE ORDERED WITH RESPECT TO THE
!+                GLOBAL NUMBER OF THE FIRST AND SECOND POINT OF
!+                EVERY SEGMENT, SO THAT THE PROCESSORS SHARE THE
!+                INFORMATION ON THE SAME SEGMENTS.
!
!history  C. DENIS
!+        22/07/2009
!+        V6P0
!+   AVOIDS THE (TOO) LARGE INTEGERS OF 5.9 RELEASE
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        13/07/2010
!+        V6P0
!+   Translation of French comments within the FORTRAN sources into
!+   English comments
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        21/08/2010
!+        V6P0
!+   Creation of DOXYGEN tags for automated documentation and
!+   cross-referencing of the FORTRAN sources
!
!history  J-M HERVOUET
!+        09/09/2017
!+        V7P3
!+   Local NELEM renamed DIM1ELTSEG, it is not always equal to NELEM,
!+   it is in fact NELMAX.
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!| DIM1ELTSEG     |-->| FIRST DIMENSION OF ELTSEG
!| DIM1NHCOM      |-->| FIRST DIMENSION OF NH_COM_SEG
!| DIMGLO         |-->| FIRST DIMENSION OF GLOSEG
!| ELTSEG         |-->| GIVES THE SEGMENT NUMBER OF EDGES OF ELEMENTS
!| GLOSEG         |-->| GLOBAL NUMBERS (IN SUB-DOMAIN) OF POINTS
!|                |   | OF A SEGMENT
!| KNOLG          |-->| GLOBAL NUMBERS (WHOLE MESH) FUNCTION OF
!|                |   | LOCAL NUMBERS OF POINTS
!| NB_NEIGHB_SEG  |-->| NUMBER OF NEIGHBOUR PROCESSOR (FOR SEGMENTS)
!| NH_COM_SEG     |-->| ADDRESSES OF INTERFACE SEGMENTS
!| NPOIN          |-->| NUMBER OF POINTS
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      USE declarations_special
      IMPLICIT NONE
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER, INTENT(IN)    :: DIM1ELTSEG,DIM1NHCOM,NB_NEIGHB_SEG
      INTEGER, INTENT(IN)    :: DIMGLO,NPOIN
      INTEGER, INTENT(INOUT) :: NH_COM_SEG(dim1nhcom,nb_neighb_seg)
      INTEGER, INTENT(IN)    :: ELTSEG(dim1eltseg,3),GLOSEG(dimglo,2)
      INTEGER, INTENT(IN)    :: NB_NEIGHB_PT_SEG(nb_neighb_seg)
      INTEGER, INTENT(IN)    :: KNOLG(npoin)
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER IELEM,IFACE,ISEG,IPROC,IKA,I,J,B,NUMSEG
      INTEGER I11,I12,I21,I22
      LOGICAL IS_LE_THAN
!
!-----------------------------------------------------------------------
!
      DO iproc=1,nb_neighb_seg
        ika = nb_neighb_pt_seg(iproc)
        DO iseg=1,ika
          iface=mod(nh_com_seg(iseg,iproc),4)
          ielem=(nh_com_seg(iseg,iproc)-iface)/4
          numseg=eltseg(ielem,iface)
          nh_com_seg(iseg,iproc)=numseg
        ENDDO
        IF(ika.GT.1) THEN
          DO j=2,ika
            b=nh_com_seg(j,iproc)
            DO i=j-1,1,-1
              numseg=nh_com_seg(i,iproc)
              i11=knolg(gloseg(numseg,1))
              i12=knolg(gloseg(numseg,2))
              i21=knolg(gloseg(b     ,1))
              i22=knolg(gloseg(b     ,2))
              IF(i11.GT.i21) THEN
                is_le_than=.false.
              ELSEIF(i11.LT.i21) THEN
                is_le_than=.true.
              ELSEIF(i11.EQ.i21.AND.i12.GT.i22) THEN
                is_le_than=.false.
              ELSEIF(i11.EQ.i21.AND.i12.LT.i22) THEN
                is_le_than=.true.
              ELSEIF(i11.EQ.i21.AND.i12.EQ.i22) THEN
                is_le_than=.true.
              ELSE
                WRITE(lu,*) 'UNEXPECTED CASE IN COMP_NH_COM_SEG'
                CALL plante(1)
                stop
              ENDIF
              IF(is_le_than) GO TO 10
              nh_com_seg(i+1,iproc)=nh_com_seg(i,iproc)
            ENDDO
 10         CONTINUE
            nh_com_seg(i+1,iproc)=b
          ENDDO
        ENDIF
      ENDDO
!
!-----------------------------------------------------------------------
!
      RETURN
      END