coefro_sisyphe.f

Go to the documentation of this file.

!                   *************************
                    SUBROUTINE coefro_sisyphe
!                   *************************
!
     &(cf,h,kfrot,chestr,grav,npoin,hmin,karman)
!
!***********************************************************************
! SISYPHE   V6P1                                   21/07/2011
!***********************************************************************
!
!brief    COMPUTES THE QUADRATIC FRICTION COEFFICIENT CF.
!
!history  C. VILLARET (LNHE)
!+        01/10/2003
!+        V5P4
!+
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        13/07/2010
!+        V6P0
!+   Translation of French comments within the FORTRAN sources into
!+   English comments
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        21/08/2010
!+        V6P0
!+   Creation of DOXYGEN tags for automated documentation and
!+   cross-referencing of the FORTRAN sources
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!| CF             |<->| FRICTION COEFFICIENT
!| CHESTR         |-->| FRICTION COEFFICIENTS (BED)
!| GRAV           |-->| ACCELERATION OF GRAVITY
!| HMIN           |-->| MINIMUM VALUE OF WATER DEPTH
!| HN             |-->| WATER DEPTH
!| KARMAN         |-->| VON KARMAN CONSTANT
!| KFROT          |-->| FRICTION LAW (BED)
!| NPOIN          |-->| NUMBER OF POINTS
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      USE bief
!
      USE declarations_special
      IMPLICIT NONE
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER, INTENT(IN):: NPOIN,KFROT
      DOUBLE PRECISION,INTENT(IN):: GRAV,KARMAN,HMIN
!
      TYPE(bief_obj), INTENT(INOUT) :: CF
      TYPE(bief_obj),INTENT(IN) :: CHESTR,H
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER N
      DOUBLE PRECISION HC, AUX, TIERS,ZERO
      INTRINSIC max,log
!
!-----------------------------------------------------------------------
!
      tiers  = 1.d0/3.d0
      zero = 1.d-6
!
!  CONSTRUCTION OF THE FRICTION COEFFICIENT
!
!     FRICTION LAWS:
!
!     KFROT = 0 :  FLAT BOTTOM  (KS=3D50)
!     KFROT = 1 :  EQUILIBRIUM SAND RIPPLES (WAVES ONLY) KS=(MAX 3D50,ETA)
!     KFROT = 2 :  CHEZY
!     KFROT = 3 :  STRICKLER
!     KFROT = 4 :  MANNING
!     KFROT = 5 :  NIKURADSE
!
      DO n=1,npoin
        IF(chestr%R(n).LE.0.d0) THEN
          WRITE(lu,*) 'FROTTEMENT NON DEFINI DANS COEFRO AU POINT ',n
          CALL plante(1)
          stop
        ENDIF
      ENDDO
!
!     ***********************
      IF(kfrot.EQ.5) THEN
!    ***********************
!          AUX=30.D0/EXP(1.D0) =11.036D0
        DO n=1,npoin
            aux = max(1.001d0,h%R(n)*11.036d0/chestr%R(n))
            cf%R(n) = 2.d0 / (log( aux)/karman )**2
        ENDDO
!     ***********************
      ELSEIF(kfrot.EQ.2) THEN
!     ***********************
!
        DO n=1,npoin
          cf%R(n) = 2.d0 * grav / chestr%R(n)**2
        ENDDO
!
!     ***********************
      ELSEIF(kfrot.EQ.3) THEN
!     ***********************
!
        DO n=1,npoin
          hc = max(h%R(n),hmin)
          cf%R(n) = 2.d0 * grav / chestr%R(n)**2 / hc**tiers
        ENDDO
!
!     ***********************
      ELSEIF(kfrot.EQ.4) THEN
!     ***********************
!
        DO n=1,npoin
          hc = max(h%R(n),hmin)
          cf%R(n) = 2.d0 * chestr%R(n)**2 * grav / hc**tiers
        ENDDO
!
!     ****
      ELSE
!     ****
!
        WRITE(lu,301) kfrot
301     FORMAT(1x,'COEFRO: UNKNOWN LAW OF BOTTOM FRICTION: ',1i6)
        CALL plante(1)
        stop
!
!     *****
      ENDIF
!     *****
!
!-----------------------------------------------------------------------
!
      RETURN
      END