coef.f

Go to the documentation of this file.

!                   ***************
                    SUBROUTINE coef
!                   ***************
!
     &     (s3d_ivide, s3d_epai, tra01 ,
     &      s3d_npfmax, imax , ndeb  ,
     &      s3d_rhos, grav , s3d_dtc, dsig1    )
!
!***********************************************************************
! TELEMAC3D   V6P1                                   21/08/2010
!***********************************************************************
!
!brief    COMPUTES THE COEFFICIENTS RESULTING FROM THE
!+                DISCRETISATION OF THE DIFFERENTIAL EQUATION GOVERNING
!+                THE CONSOLIDATION OF MUDDY BEDS.
!
!history  C LE NORMANT (LNH)
!+        13/05/92
!+        V5P1
!+
!
!history  JACEK A. JANKOWSKI PINXIT
!+        **/03/99
!+
!+   FORTRAN95 VERSION
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        13/07/2010
!+        V6P0
!+   Translation of French comments within the FORTRAN sources into
!+   English comments
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        21/08/2010
!+        V6P0
!+   Creation of DOXYGEN tags for automated documentation and
!+   cross-referencing of the FORTRAN sources
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!| DSIG1          |-->| DERIVATIVE OF THE EFFECTIVE STRESS
!|                |   | AT THE FIRST POINT OF THE MESH
!| GRAV           |-->| GRAVITY ACCELERATION
!| IMAX           |-->| NUMBER OF POINTS AT THE BOTTOM MESH
!| NDEB           |-->| INDEX LIMITING THE RANGE OF RESOLUTION
!| S3D_DTC        |-->| TIME STEP FOR CONSOLIDATION
!| S3D_EPAI       |-->| THICKNESS OF MESH ELEMENTS DISCRETISING THE BED
!| S3D_IVIDE      |-->| INDEX OF EMPTY SPACES AT MESH POINTS
!| S3D_NPFMAX     |-->| MAXIMUM NUMBER OF HORIZONTAL PLANES THAT
!|                |   | DISCRETISE MUDDY BOTTOM
!| S3D_RHOS       |-->| SEDIMENT DENSITY
!| TRA01          |<->| WORKING ARRAY
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      IMPLICIT NONE
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER, INTENT(IN) ::  S3D_NPFMAX, IMAX,NDEB
!
      DOUBLE PRECISION, INTENT(INOUT) :: TRA01(s3d_npfmax,6)
      DOUBLE PRECISION, INTENT(IN) :: S3D_EPAI(s3d_npfmax-1)
      DOUBLE PRECISION, INTENT(IN) :: S3D_IVIDE(s3d_npfmax)
      DOUBLE PRECISION, INTENT(IN) :: S3D_RHOS, GRAV ,S3D_DTC, DSIG1
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER I
      DOUBLE PRECISION A , D
!
!=======================================================================
!
!      -----INITIALISES THE COEFFICIENTS-----
!
      DO i=ndeb,imax
        tra01(i,3)=0.d0
        tra01(i,4)=1.d0
        tra01(i,5)=0.d0
        tra01(i,6)=0.d0
      END DO
!
!     -----COMPUTES THE COEFFICIENTS AT THE MESH NODES-----
!
!     ...NODE ON THE BOTTOM:
      tra01(ndeb,5)=-1.d0
      tra01(ndeb,6)=(s3d_rhos-1000.d0)*grav*s3d_epai(1)/dsig1
!
!     ...INTERIOR NODE:
      DO i=ndeb+1,imax-1
!
        IF (tra01(i,1).GE.1.d-10) THEN
          a=tra01(i,1)/(s3d_epai(i-1))
          d=1.d0
        ELSE
          a=tra01(i,1)/(s3d_epai(i))
          d=0.d0
        ENDIF
!
        tra01(i,3)=s3d_dtc*(-(tra01(i,2)+tra01(i-1,2))/((s3d_epai(i)+
     &             s3d_epai(i-1))*s3d_epai(i-1))-d*a)
        tra01(i,5)=s3d_dtc*((1.d0-d)*a-((tra01(i,2)+tra01(i+1,2))
     &                /((s3d_epai(i)+s3d_epai(i-1))*s3d_epai(i))))
        tra01(i,4)=1.d0-tra01(i,3)-tra01(i,5)
        tra01(i,6)=s3d_ivide(i)
!
      END DO
!
!     ...INTERFACE NODE:
      tra01(imax,6)=s3d_ivide(imax)
!
      RETURN
      END SUBROUTINE coef