circul.f

Go to the documentation of this file.

!                       *****************
                        SUBROUTINE circul
!                       *****************
!
     &(ikle,itest1 ,ielem,i1,i2,i3,x,y,nnelmax)
!
!***********************************************************************
!  STBTEL VERSION 5.2   16/08/89    J.C. GALLAND   (LNH)
!***********************************************************************
!
!    FONCTION : CALCUL DE L'AIRE FORMEE PAR LES TROIS POINTS I1,I2,I3
!               ET PERMUTATION DES POINTS I2 ET I3 LORSQU'ELLE EST
!               NEGATIVE.
!
!-----------------------------------------------------------------------
!                             ARGUMENTS
! .________________.____.______________________________________________.
! |      NOM       |MODE|                   ROLE                       |
! |________________|____|______________________________________________|
! |    IKLE        |<-->| NUMEROS GLOBAUX DES POINTS DE CHAQUE ELEMENT |
! |    ITEST1      | -->| COMPTEUR                                     |
! |    IELEM       | -->| NUMERO DE L'ELEMENT COURANT                  |
! |    I1,I2,I3    | -->| PERMUTATION DES IKLE                         |
! |    X,Y         | -->| COORDONNEES DES POINTS DU MAILLAGE           |
! |________________|____|______________________________________________
! | COMMON:        |    |
! |  GEO:          |    |
! |    NDP         | -->| NOMBRE DE NOEUDS PAR ELEMENTS
! |    NPOIN       | -->| NOMBRE TOTAL DE NOEUDS DU MAILLAGE
! |    NELEM       | -->| NOMBRE TOTAL D'ELEMENTS DU MAILLAGE
! |    NPMAX       | -->| DIMENSION EFFECTIVE DES TABLEAUX X ET Y
! |                |    | (NPMAX = NPOIN + 0.1*NELEM)
! |    NNELMAX     | -->| DIMENSION EFFECTIVE DES TABLEAUX CONCERNANT
! |                |    | LES ELEMENTS (NNELMAX = NELEM + 0.2*NELEM)
! |________________|____|______________________________________________|
!  MODE: -->(DONNEE NON MODIFIEE),<--(RESULTAT),<-->(DONNEE MODIFIEE)
!-----------------------------------------------------------------------
! APPELE PAR : LECSTB
! APPEL DE :
!***********************************************************************
!
      USE declarations_special
      USE declarations_stbtel
      IMPLICIT NONE
!
      INTEGER, INTENT(IN) :: NNELMAX
      INTEGER, INTENT(IN) :: IELEM
      INTEGER, INTENT(INOUT) :: IKLE(nnelmax,4)
      INTEGER, INTENT(IN) :: I1 , I2 , I3
      INTEGER, INTENT(INOUT) :: ITEST1
      DOUBLE PRECISION, INTENT(IN) :: X(*),Y(*)

      INTEGER I
!
      DOUBLE PRECISION X2 , X3 , Y2 , Y3
      DOUBLE PRECISION AIRE
!
!
      x2 = x(ikle(ielem,i2))-x(ikle(ielem,i1))
      x3 = x(ikle(ielem,i3))-x(ikle(ielem,i1))
!
      y2 = y(ikle(ielem,i2))-y(ikle(ielem,i1))
      y3 = y(ikle(ielem,i3))-y(ikle(ielem,i1))
!
      aire = x2*y3 - x3*y2
!
      IF (aire.LT.0.d0) THEN
        itest1 = itest1 + 1
        i = ikle(ielem,i2)
!
        ikle(ielem,i2) = ikle(ielem,i3)
        ikle(ielem,i3) = i
      ENDIF
!
      RETURN
      END