chgdis.f

Go to the documentation of this file.

!                   *****************
                    SUBROUTINE chgdis
!                   *****************
!
     &(x,oldelt,newelt,mesh)
!
!***********************************************************************
! BIEF   V6P1                                   16/03/2011
!***********************************************************************
!
!brief    CHANGES THE DISCRETISATION OF A VECTOR.
!
!history  J-M HERVOUET (LNH)
!+        13/02/2008
!+        V5P9
!+
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        13/07/2010
!+        V6P0
!+   Translation of French comments within the FORTRAN sources into
!+   English comments
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        21/08/2010
!+        V6P0
!+   Creation of DOXYGEN tags for automated documentation and
!+   cross-referencing of the FORTRAN sources
!
!history  J-M HERVOUET (LNHE)
!+        16/03/2011
!+        V6P1
!+        SEQUENCE: X%DIM1 = NEWDIM1
!+                  X%ELM  = NEWELT
!+        MOVED AT THE END, CHGDIS MAY BE CALLED WITH X%ELM BEING OLDELT
!+        THEN IT MAKES OLDELT=NEWELT WHEREAS OLDELT WAS INTENT(IN) AND
!+        SHOULD NOT BE CHANGED BEFORE TESTS ON IT.
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!| MESH           |-->| MESH STRUCTURE
!| NEWELT         |-->| NEW TYPE FOR X
!| OLDELT         |-->| OLD TYPE OF X
!| X              |<--| VECTOR TO BE MODIFIED
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      USE bief, ex_chgdis => chgdis
!
      USE declarations_special
      IMPLICIT NONE
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      TYPE(bief_obj), INTENT(INOUT) :: X
      INTEGER, INTENT(IN)           :: NEWELT
      INTEGER, INTENT(INOUT)        :: OLDELT
      TYPE(bief_mesh), INTENT(IN)   :: MESH
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER NEWDIM1
!
!-----------------------------------------------------------------------
!
      newdim1 = bief_nbpts(newelt,mesh)
!
      IF(newdim1.GT.x%MAXDIM1) THEN
        WRITE(lu,201) x%NAME
201     FORMAT(1x,'CHGDIS (BIEF) : EXTENSION IMPOSSIBLE FOR ',a6)
        CALL plante(1)
        stop
      ENDIF
!
!-----------------------------------------------------------------------
!
      IF(oldelt.EQ.11.AND.newelt.EQ.12) THEN
!
        CALL cg1112(x%R,newdim1,x%DIM2,
     &              mesh%IKLE%I,mesh%NELEM,mesh%NELMAX)
!
      ELSEIF(oldelt.EQ.11.AND.newelt.EQ.13) THEN
!
        CALL cg1113(x%R,newdim1,x%DIM2,
     &              mesh%IKLE%I,mesh%NELEM,mesh%NELMAX)
!
      ELSEIF((oldelt.EQ.12.OR.oldelt.EQ.13).AND.newelt.EQ.11) THEN
!
!       DOES NOTHING (QUASI-BUBBLE OR QUADRATIC VALUES JUST LOST)
!
      ELSE
!
        WRITE(lu,11) oldelt,newelt
11      FORMAT(1x,'CHGDIS: CASE NOT IMPLEMENTED:',i6,' ',i6)
        WRITE(lu,*) 'STRUCTURE X = ',x%NAME
        CALL plante(1)
        stop
!
      ENDIF
!
      x%DIM1 = newdim1
!     THIS MAY BE A HIDDEN MODIFICATION OF OLDELT, IF X%ELM IS SENT AS
!     OLDELT, HENCE THE INTENT(INOUT) FOR OLDELT.
      x%ELM  = newelt
!
!-----------------------------------------------------------------------
!
      RETURN
      END