check_digits.f

Go to the documentation of this file.

!                   ***********************
                    SUBROUTINE check_digits
!                   ***********************
!
     &(f,t1,mesh)
!
!***********************************************************************
! BIEF   V6P1                                   21/08/2010
!***********************************************************************
!
!brief    IN PARALLEL MODE, CHECKS THAT PROCESSORS SHARING AN
!+                INTERFACE POINT HAVE EXACTLY THE SAME VALUE FOR ARRAY F.
!
!history  J-M HERVOUET (LNHE)
!+        02/06/08
!+        V5P9
!+
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        13/07/2010
!+        V6P0
!+   Translation of French comments within the FORTRAN sources into
!+   English comments
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        21/08/2010
!+        V6P0
!+   Creation of DOXYGEN tags for automated documentation and
!+   cross-referencing of the FORTRAN sources
!
!history  J,RIEHME (ADJOINTWARE)
!+        November 2016
!+        V7P2
!+   Replaced EXTERNAL statements to parallel functions / subroutines
!+   by the INTERFACE_PARALLEL
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!| F              |-->| BIEF_OBJ STRUCTURE TO BE CHECKED
!| MESH           |-->| MESH STRUCTURE
!| T1             |<->| WORK BIEF STRUCTURE, SIMILAR TO F
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      USE bief
!
      USE declarations_special
      USE interface_parallel, ONLY : p_max
      IMPLICIT NONE
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      TYPE(bief_obj),  INTENT(IN   ) :: F
      TYPE(bief_obj),  INTENT(INOUT) :: T1
      TYPE(bief_mesh), INTENT(INOUT) :: MESH
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER I,ISTOP
!
!-----------------------------------------------------------------------
!
      CALL os('X=Y     ',x=t1,y=f)
      CALL parcom(t1,3,mesh)
      istop=0
      DO i=1,t1%DIM1
        IF(t1%R(i).NE.f%R(i)) THEN
          WRITE(lu,*) 'CHECK_DIGITS : DIFFERENCE IN ',f%NAME
          WRITE(lu,*) '               AT LOCAL POINT ',i
          WRITE(lu,*) '               =  GLOBAL POINT ',mesh%KNOLG%I(i)
          WRITE(lu,*) '               VALUE ',f%R(i)
          WRITE(lu,*) '               MINIMUM ',t1%R(i)
          WRITE(lu,*) '            DIFFERENCE ',f%R(i)-t1%R(i)
          istop=i
        ENDIF
      ENDDO
!
      IF(ncsize.GT.1) istop=p_max(istop)
      IF(istop.GT.0) THEN
        WRITE(lu,*) 'CHECK_DIGITS : ERROR ON VECTOR ',f%NAME
        CALL plante(1)
        stop
      ENDIF
!
!-----------------------------------------------------------------------
!
      RETURN
      END