cflpsi.f

Go to the documentation of this file.

!                   *****************
                    SUBROUTINE cflpsi
!                   *****************
!
     &(sygma,u,v,dt,ielm,mesh,msk,maskel)
!
!***********************************************************************
! BIEF   V7P0                                   21/08/2010
!***********************************************************************
!
!brief    COMPUTES THE COURANT NUMBER AT EACH POINT OF THE MESH
!+                AND FOR EACH TIMESTEP.
!
!warning  THE COORDINATES ARE HERE GIVEN BY ELEMENTS
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        13/07/2010
!+        V6P0
!+   Translation of French comments within the FORTRAN sources into
!+   English comments
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        21/08/2010
!+        V6P0
!+   Creation of DOXYGEN tags for automated documentation and
!+   cross-referencing of the FORTRAN sources
!
!history  J-M HERVOUET (EDF LAB, LNHE)
!+        07/05/2014
!+        V7P0
!+   Correction in //, SYGMA was not assembled.
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!| DT             |-->| TIME STEP.
!| IELM           |-->| TYPE OF ELEMENT.
!| MASKEL         |-->| MASKING OF ELEMENTS
!|                |   | =1. : NORMAL   =0. : MASKED ELEMENT
!| MESH           |-->| MESH STRUCTURE
!| MSK            |-->| IF YES, THERE IS MASKED ELEMENTS.
!| SYGMA          |<--| COURANT NUMBER.
!| U              |-->| VELOCITY ALONG X.
!| V              |-->| VELOCITY ALONG Y.
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      USE bief, ex_cflpsi => cflpsi
!
      USE declarations_special
      IMPLICIT NONE
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      TYPE(bief_obj)  , INTENT(INOUT) :: SYGMA
      TYPE(bief_obj)  , INTENT(IN)    :: U,V,MASKEL
      DOUBLE PRECISION, INTENT(IN)    :: DT
      INTEGER         , INTENT(IN)    :: IELM
      TYPE(bief_mesh) , INTENT(INOUT) :: MESH
      LOGICAL         , INTENT(IN)    :: MSK
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
!     MASS OF THE BASES IN BIEF WORKING ARRAY
!
      CALL vector(mesh%T,'=','MASBAS          ',
     &            ielm,1.d0,u,u,u,u,u,u,mesh,msk,maskel)
!
      IF(ncsize.GT.1) CALL parcom(mesh%T,2,mesh)
!
      CALL cpstvc(mesh%T,sygma)
!
!-----------------------------------------------------------------------
!
!     P1 TRIANGLES
!
      IF(ielm.EQ.11) THEN
!
        CALL cflp11(u%R,v%R,mesh%XEL%R,mesh%YEL%R,
     &              mesh%IKLE%I,mesh%NELEM,mesh%NELMAX,mesh%W%R)
!
!-----------------------------------------------------------------------
!
!     QUASI-BUBBLE TRIANGLES
!
      ELSEIF(ielm.EQ.12) THEN
!
        CALL cflp12(u%R,v%R,mesh%XEL%R,mesh%YEL%R,
     &              mesh%IKLE%I,mesh%NELEM,mesh%NELMAX,mesh%W%R)
!
!-----------------------------------------------------------------------
!
      ELSE
!
        WRITE(lu,101) ielm
101     FORMAT(1x,'CFLPSI: IELM = ',1i6,' CASE NOT IMPLEMENTED.')
        CALL plante(1)
        stop
!
      ENDIF
!
! ASSEMBLES THE LIJ
!
      CALL assvec(sygma%R,mesh%IKLE%I,bief_nbpts(ielm,mesh),
     &            mesh%NELEM,mesh%NELMAX,
     &            mesh%W%R,.true.,mesh%LV,msk,maskel%R,
     &            bief_nbpel(ielm,mesh))
      IF(ncsize.GT.1) CALL parcom(sygma,2,mesh)
!
!-----------------------------------------------------------------------
!
! FINAL RESULT, DIVIDES BY THE MASS OF THE BASES
!
      CALL os('X=CY/Z  ', x=sygma, y=sygma, z=mesh%T, c=dt,
     &                    iopt=2, infini=0.d0, zero=1.d-6)
!
!-----------------------------------------------------------------------
!
      RETURN
      END