cflp11.f

Go to the documentation of this file.

!                   *****************
                    SUBROUTINE cflp11
!                   *****************
!
     &(u,v,x,y,ikle,nelem,nelmax,w1)
!
!***********************************************************************
! BIEF   V6P1                                   21/08/2010
!***********************************************************************
!
!brief    COMPUTES THE COURANT NUMBER AT EACH POINT OF THE MESH
!+                AND FOR EACH TIMESTEP.
!+
!+            THE STABILITY CRITERION OF THE DISTRIBUTIVE SCHEME N
!+                IS HERE USED TO EVALUATE THE COURANT NUMBER.
!
!history  JMH
!+        17/08/94
!+        V5P1
!+
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        13/07/2010
!+        V6P0
!+   Translation of French comments within the FORTRAN sources into
!+   English comments
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        21/08/2010
!+        V6P0
!+   Creation of DOXYGEN tags for automated documentation and
!+   cross-referencing of the FORTRAN sources
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!| IKLE           |-->| CONNECTIVITY TABLE
!| NELEM          |-->| NUMBER OF ELEMENTS IN THE MESH
!| NELMAX         |-->| FIRST DIMENSION OF IKLE, MAXIMUM NUMBER OF ELEMENTS
!|                |   | IN THE MESH
!| U              |-->| VELOCITY ALONG X.
!| V              |-->| VELOCITY ALONG Y.
!| W1             |-->| RESULT IN NON ASSEMBLED FORM
!| X              |-->| ABSCISSAE OF POINTS GIVEN PER ELEMENT
!| Y              |-->| ORDINATES OF POINTS GIVEN PER ELEMENT
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      USE declarations_special
      IMPLICIT NONE
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER         , INTENT(IN)  :: NELEM,NELMAX
      DOUBLE PRECISION, INTENT(IN)  :: U(*),V(*)
      DOUBLE PRECISION, INTENT(IN)  :: X(nelmax,*),Y(nelmax,*)
      INTEGER         , INTENT(IN)  :: IKLE(nelmax,*)
!     NO DEFAULT INITIALISATION FOR USER TYPE COMPONENTS ALLOWED
      DOUBLE PRECISION, INTENT(INOUT) :: W1(nelmax,*)
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER IELEM
!
      DOUBLE PRECISION U1,U2,U3,V1,V2,V3,USUR2,VSUR2
      DOUBLE PRECISION SUR6,K1,K2,K3,L12,L13,L21,L23,L31,L32
      DOUBLE PRECISION X2,X3,Y2,Y3
!
      INTRINSIC max,min
!
!-----------------------------------------------------------------------
!
      sur6 = 1.d0 / 6.d0
!
! LOOP ON THE ELEMENTS
!
        DO ielem = 1, nelem
!
          x2 = x(ielem,2)
          x3 = x(ielem,3)
          y2 = y(ielem,2)
          y3 = y(ielem,3)
!
          u1 = u(ikle(ielem,1))
          u2 = u(ikle(ielem,2))
          u3 = u(ikle(ielem,3))
          v1 = v(ikle(ielem,1))
          v2 = v(ikle(ielem,2))
          v3 = v(ikle(ielem,3))
!
          usur2 = (u1+u2+u3)*sur6
          vsur2 = (v1+v2+v3)*sur6
!
          k1 = usur2 * (y2-y3) - vsur2 * (x2-x3)
          k2 = usur2 * (y3   ) - vsur2 * (x3   )
          k3 = usur2 * (  -y2) - vsur2 * (  -x2)
!
          l12 = max(  min(k1,-k2) , 0.d0 )
          l13 = max(  min(k1,-k3) , 0.d0 )
          l21 = max(  min(k2,-k1) , 0.d0 )
          l23 = max(  min(k2,-k3) , 0.d0 )
          l31 = max(  min(k3,-k1) , 0.d0 )
          l32 = max(  min(k3,-k2) , 0.d0 )
!
          w1(ielem,1) = l12 + l13
          w1(ielem,2) = l21 + l23
          w1(ielem,3) = l31 + l32
!
        ENDDO ! IELEM
!
!-----------------------------------------------------------------------
!
      RETURN
      END