caltetap.f

Go to the documentation of this file.

!                   *******************
                    SUBROUTINE caltetap
!                   *******************
     &(teta,xsgbor,ysgbor,adir,nptfr)
!
!
!***********************************************************************
! ARTEMIS   V7P3                                     Aug 2017
!***********************************************************************
!
!brief    COMPUTES ANGLE TETAP ON THE BOUNDARY FROM THE WAVE INCIDENCE
!+        ON THE DOMAIN
!         TETAP is given in degrees, in the interval [0 ; 90]
!
!history  C. PEYRARD (LNHE)
!+        18/03/2014
!+        V7P0
!+        NEW SUBROUTINE CREATED / IMPLEMENTED
!
!history  N.DURAND (HRW)
!+        August 2017
!+        V7P3
!+   RADDEG now defined in DECLARATIONS_ARTEMIS
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!| TETA           |-->| ANGLE BETWEEN WAVE DIRECTION AND BOUNDARY NORMAL
!                       (TETAP)
!| XSGBOR         |-->| X COMPONENT OF THE NORMAL TO THE BOUNDARY SEGMENT
!| YSGBOR         |-->| Y COMPONENT OF THE NORMAL TO THE BOUNDARY SEGMENT
!| ADIR           |-->| INCIDENCE ANGLE OF WAVES
!| NPTFR          |-->| NUMBER OF BOUNDARY POINTS
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      USE bief
!
      USE declarations_special
      USE declarations_artemis, ONLY : raddeg
      IMPLICIT NONE
!
      INTEGER I,NPTFR
!
      DOUBLE PRECISION PSCALA,XNA,YNA,XI,YI,PSCALB,XNB,YNB
      DOUBLE PRECISION, INTENT(IN)  :: XSGBOR(nptfr,4),YSGBOR(nptfr,4)
      DOUBLE PRECISION              :: TETA(nptfr),ADIR(nptfr)
!
      INTRINSIC sqrt, atan2, mod, abs, cos, sin, atan
!
!-----------------------------------------------------------------------
!
      DO i=1,nptfr
!
!       STEP 1 : VECTOR NORMAL TO "THE POINT" (SEGMENT AFTER/BEFORE)
!       ======================================================
!       NORMAL TO SEGMENT AFTER
        xna=xsgbor(i,1)
        yna=ysgbor(i,1)
!       NORMAL TO SEGMENT BEFORE
        xnb=xsgbor(i,2)
        ynb=ysgbor(i,2)
!       NORMALIZATION NOT NECESSARY AS (XSGBOR(K,1),YSGBOR(K,1)) AND
!       (XSGBOR(K,2),YSGBOR(K,2)) ARE ALREADY OF NORM 1
!
!       STEP 2 : VECTOR INCIDENCE AT NODE
!       =========================
        xi=cos(adir(i))
        yi=sin(adir(i))
!
!       STEP 3 : ANGLE BETWEEN NORMAL DIRECTION AND INCIDENCE DIRECTION
!       ===============================================================
        pscala=xna*xi+yna*yi
        pscalb=xnb*xi+ynb*yi
!       SMALLEST ANGLE BETWEEN NORMAL AND INCIDENCE (0<TETAP<90)
        IF(pscala.LT.0d0) THEN
          pscala=-pscala
        ENDIF
        IF(pscalb.LT.0d0) THEN
          pscalb=-pscalb
        ENDIF
!
!       STEP 4 = TETAP IS GIVEN IN DEGRES
!       =================================
!       CHOOSE OF THE LOWER VALUE OF TETA (SEEMS BETTER AT CORNER CONSIDERING
!       THE PHBOR ROUTINE RULES)
        teta(i)=min(acos(pscala)*raddeg,acos(pscalb)*raddeg)
      ENDDO
!=======================================================================
!
      RETURN
      END