calcuw.f

Go to the documentation of this file.

!                   *****************
                    SUBROUTINE calcuw
!                   *****************
!
     & ( uw, h, hw, tw, grav ,npoin)
!
!***********************************************************************
! SISYPHE   V6P1                                   21/07/2011
!***********************************************************************
!
!brief    COMPUTES THE WAVE ORBITAL VELOCITY.
!
!history
!+        20/05/96
!+        V5P1
!+
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        13/07/2010
!+        V6P0
!+   Translation of French comments within the FORTRAN sources into
!+   English comments
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        21/08/2010
!+        V6P0
!+   Creation of DOXYGEN tags for automated documentation and
!+   cross-referencing of the FORTRAN sources
!
!history  C.VILLARET (EDF-LNHE), P.TASSI (EDF-LNHE)
!+        19/07/2011
!+        V6P1
!+  Name of variables
!+
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!| GRAV           |-->| ACCELERATION OF GRAVITY
!| H              |-->| WATER DEPTH
!| HW             |-->| WAVE DEPTH
!| NPOIN          |-->| NUMBER OF POINTS
!| TW             |-->| WAVE PERIOD
!| UW             |<--| ORBITAL VELOCITY (WAVE)
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      IMPLICIT NONE
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER, INTENT(IN) :: NPOIN
      DOUBLE PRECISION, INTENT(INOUT) :: UW(npoin)
      DOUBLE PRECISION, INTENT(IN) :: TW(npoin),H(npoin), HW(npoin)
      DOUBLE PRECISION, INTENT(IN) :: GRAV
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      DOUBLE PRECISION   PI,DPI2
      DOUBLE PRECISION   POL, Y ,X
      INTEGER I
      INTRINSIC sqrt, sinh, atan
!
!-----------------------------------------------------------------------
!
      pi = 4.d0 * atan( 1.d0 )
      dpi2 = 4.d0 * pi * pi
!
!  SOLVES Y=X*TH(X) WITH Y=(2*PI/TW)**2*H/G AND X=(2*PI/L)*H
!  USING A POLYNOMIAL FUNCTION (HUNT METHOD - 9TH ORDER)
!
      DO i=1,npoin
        IF ( (tw(i) .GT. 0.d0).AND.(hw(i).GT.0.d0) ) THEN
          y = dpi2 / grav * h(i) / (tw(i) * tw(i))
          pol = 1.d0 + y * ( 0.66667d0 +
     &                y * ( 0.35550d0 +
     &                y * ( 0.16084d0 +
     &                y * ( 0.06320d0 +
     &                y * ( 0.02174d0 +
     &                y * ( 0.00654d0 +
     &                y * ( 0.00171d0 +
     &                y * ( 0.00039d0 +
     &                y * ( 0.00011d0 ) ))))))))
          x = sqrt( y*y + y / pol )
!
          IF ( x .GT. 10.d0) THEN
            uw(i) = 0.d0
          ELSE
            uw(i) = pi / tw(i) * hw(i) / (sinh(x))
          ENDIF
        ELSE
          uw(i) = 0.d0
        ENDIF
      ENDDO
      RETURN
      END SUBROUTINE calcuw