calctm.f

Go to the documentation of this file.

!                   *****************
                    SUBROUTINE calctm
!                   *****************
!
!
!***********************************************************************
! ARTEMIS   V7P3                                     Aug 2017
!***********************************************************************
!
!brief    COMPUTES VARIOUS ESTIMATES OF THE MEAN WAVE
!+                PERIOD :
!+                    T01 = M0/M1;
!+                    T02 = SQRT(M0/M2);
!+                    TM.
!+
!+           (DEFINITIONS IN THE LIST OF PARAMETERS ESTABLISHED
!+                BY THE IAHR)
!
!history  J-M HERVOUET (LNH)
!+
!+
!+   LINKED TO BIEF 5.0
!
!history  D. AELBRECHT (LNH)
!+        04/06/1999
!+        V5P1
!+
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        13/07/2010
!+        V6P0
!+   Translation of French comments within the FORTRAN sources into
!+   English comments
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        21/08/2010
!+        V6P0
!+   Creation of DOXYGEN tags for automated documentation and
!+   cross-referencing of the FORTRAN sources
!
!history  C.PEYRARD (LNHE)
!+        06/2014
!+        V7P0
!+   Modification of PONDER (done in artemis.f now)
!
!history  N.DURAND (HRW)
!+        August 2017
!+        V7P3
!+   Removed unnecessary references to PI and RADDEG
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      USE bief
      USE declarations_telemac
      USE declarations_artemis
!
      USE declarations_special
      IMPLICIT NONE
!
      DOUBLE PRECISION PONDER
!
!     INTRINSIC SQRT, ATAN2, MOD, ABS, COS, SIN
!
!-----------------------------------------------------------------------
!
! STRUCTURES
!
!
!-----------------------------------------------------------------------
!
      ponder = 1.d0
!
!=======================================================================
! COMPUTES M0 MOMENTUM AND STORES IT IN T2
!=======================================================================
!
      CALL os('X=YZ    ', x=t1 , y=hho  , z=hho)
      CALL os('X=CX    ', x=t1 , c=ponder)
      CALL os('X=Y+Z   ', x=t2 , y=hale , z=t1)
!
!=======================================================================
! T01 = M0 / M1 (adverage period from adverae frequency)
!=======================================================================
!
      CALL os('X=Y     ', x=t3 , y=t01)
      CALL os('X=Y/Z   ', x=t01, y=t2, z=t3)
!
!=======================================================================
! T02 = SQRT( M0 / M2 ) (~ 0 - crossing period Tz)
!=======================================================================
!
      CALL os('X=Y     ', x=t3 , y=t02)
      CALL os('X=Y/Z   ', x=t1 , y=t2, z=t3)
      CALL os('X=SQR(Y)', x=t02, y=t1)
!
!=======================================================================
! TM =  MT1 / M0 (adverage period)
!=======================================================================
!
      CALL os('X=Y     ', x=t3 , y=tm)
      CALL os('X=Y/Z   ', x=tm , y=t3 , z=t2)
!
!
!=======================================================================
! MEAN DIRECTION: INCI
!=======================================================================
!
      CALL os('X=A(Y,Z)', x=inci, y=msin, z=mcos)
!
      RETURN
      END