calcs3d_thermicv.f

Go to the documentation of this file.

!                     ***************************
                      SUBROUTINE calcs3d_thermicv
!                     ***************************
!
     & (npoin3,npoin2,nplan,z,rho,ta,texp,longit,
     &  latit,at,mardat,martim)
!
!***********************************************************************
! WAQTEL   V8P2
!***********************************************************************
!
!brief   COMPUTES SOURCE TERMS FOR  WAQ THERMIC PROCESS COUPLED WITH T3D
!
!history  R. ATA
!+        21/03/2016
!+        V7P2
!+  Creation from an example in old SOURCE_TRAC (V7P0 and V7P1)
!
!history  S.E. BOURBAN (HRW)
!+        07/06/2017
!+        V7P3
!+        Indexing tracer (IND_*) to avoid conflicting naming convention
!+        between user defined tracers, water quality processes and
!+        ice processes. Introduction of the array RANK_*.
!
!history  S.E. BOURBAN (HRW)
!+        25/09/2017
!+        V7P3
!+        TEXP and TIMP are now additive to account for a variety of
!+        of sources / sinks on a given TRACER
!
!history  C.-T. PHAM (LNHE)
!+        31/07/2019
!+        V8P1
!+        Density RHO computed in drsurr in TELEMAC-3D and given to
!+        WAQTEL as optional (none in 2D) rather than computed again
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!| AT             |-->| TIME IN SECONDS
!| DT             |-->| TIME STEP
!| LONGIT         |-->| LONGITUTE OF ORIGIN POINT
!| LATIT          |-->| LATITUDE OF ORIGIN POINT
!| MASSOU         |<--| MASS OF TRACER ADDED BY SOURCE TERM
!| MAXSCE         |-->| MAXIMUM NUMBER OF SOURCES
!| NPLAN          |-->| NUMBER OF VERTICAL PLANES
!| NPOIN          |-->| NUMBER OF NODES IN THE MESH
!| PATMOS         |-->| ATMOSPHERIC PRESSURE
!| RHO            |-->| WATER DENSITY
!| TETAT          |-->| COEFFICIENT OF IMPLICITATION FOR TRACERS.
!| TEXP           |-->| EXPLICIT SOURCE TERM.
!| TN             |-->| TRACERS AT TIME N
!| TSCE           |-->| PRESCRIBED VALUES OF TRACERS AT POINT SOURCES
!| TSCEXP         |<--| EXPLICIT SOURCE TERM OF POINT SOURCES
!|                |   | IN TRACER EQUATION, EQUAL TO:
!|                |   | TSCE - ( 1 - TETAT ) TN
!| VOLU2D         |-->| BASES AREA (NON ASSEMBLED)
!| YASMI          |-->| IF YES, THERE ARE IMPLICIT SOURCE TERMS
!| Z              |-->| Z COORDINATES FOR NODES
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      USE bief_def
      USE declarations_special
      USE declarations_waqtel, ONLY: zsd,cp_eau,ind_t,solradmeteo,
     &    mextinc,extinc
      USE meteo_telemac, ONLY: ray3,cldc
      USE exchange_with_atmosphere
      USE interface_waqtel, ex_calcs3d_thermicv => calcs3d_thermicv
      IMPLICIT NONE
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER, INTENT(IN)           :: npoin2,npoin3,nplan
      INTEGER, INTENT(IN)           :: mardat(3),martim(3)
      DOUBLE PRECISION, INTENT(IN)  :: z(npoin3),latit,longit,at
      DOUBLE PRECISION, INTENT(IN)  :: rho(npoin3)
      TYPE(bief_obj), INTENT(IN)    :: ta
      TYPE(bief_obj), INTENT(INOUT) :: texp
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
!  LOCAL VARIABLES
!
      INTEGER          i,j,iplan
      DOUBLE PRECISION lamb,kd
!
      INTRINSIC exp
!
!----------------------------------------------------------------------
!
!     EXAMPLE OF PENETRATION OF THE SOLAR RADIATION
!
!     INCIDENT SOLAR RADIATION
!
!     IF(.NOT.SOLRADMETEO) THEN
!       CALL SOLRAD(RAY_SOL,NEBU,MARDAT,MARTIM,AT,LATIT,LONGIT)
!     ELSE
!!      RAY3 READ IN METEO SUBROUTINE
!       RAY_SOL = RAY3
!     ENDIF
!
      IF(mextinc.EQ.3) THEN
!       LIGHT EXTINCTION COEFFICIENT GIVEN BY THE USER
        kd = extinc
      ELSE
!       FORMULA FOR TURBID WATER WITH SECCHI LENGTH
        kd  = 1.7d0/zsd        ! 83% OF THE INCIDENT ENERGY IS ABSORBED
      ENDIF
!        SAL = 0.D0
      DO i=1,npoin2
        DO iplan=1,nplan
          IF(.NOT.solradmeteo) THEN
            CALL solrad(ray3%R(i),cldc%R(i),mardat,martim,at,latit,
     &                  longit)
          ENDIF
          j = i + (iplan-1)*npoin2
!            TREEL=TA%ADR(IND_T)%P%R(NPOIN3-NPOIN2+I)
!            IF (IND_S.NE.0) THEN
!              SAL = TA%ADR(IND_S)%P%R(NPOIN3-NPOIN2+I)
!            ENDIF
!            RO=RO0*(1.D0-(7.D0*(TREEL-4.D0)**2-750.D0*SAL)*1.D-6)
          lamb=rho(npoin3-npoin2+i)*cp_eau
          texp%ADR(ind_t)%P%R(j) = texp%ADR(ind_t)%P%R(j) +
     &      kd*exp(kd*(z(j)-z(i+(nplan-1)*npoin2)))*ray3%R(i)/lamb
!
!           EXAMPLE OF FORMULA FOR TURBID WATER
!           ALL CONSTANTS MAY BE TUNED
!           0.22D0 = 1.D0-0.78D0
!           TEXP%ADR(IND_T)%P%R(J) = TEXP%ADR(IND_T)%P%R(J) +
!           ( 0.78D0*0.66D0 *EXP(0.66D0* (Z(J)-Z(I+(NPLAN-1)*NPOIN2)))
!     &      +0.22D0*0.125D0*EXP(0.125D0*(Z(J)-Z(I+(NPLAN-1)*NPOIN2))))
!     &     *RAY3%R(I)/LAMB
!
!           EXAMPLE OF FORMULA FOR CLEAR WATER
!           ALL CONSTANTS MAY BE TUNED
!           0.42D0 = 1.D0-0.58D0
!           TEXP%ADR(IND_T)%P%R(J) = TEXP%ADR(IND_T)%P%R(J) +
!           ( 0.58D0/0.35D0*EXP((Z(J)-Z(I+(NPLAN-1)*NPOIN2))/0.35D0)
!     &      +0.42D0/23.D0 *EXP((Z(J)-Z(I+(NPLAN-1)*NPOIN2))/23.D0 ))
!     &     *RAY3%R(I)/LAMB
        ENDDO
      ENDDO
!
!-----------------------------------------------------------------------
!
      RETURN
      END