calcs2d_degradation.f

Go to the documentation of this file.

!                   ******************************
                    SUBROUTINE calcs2d_degradation
!                   ******************************
!
     &(npoin,tn,texp,timp,hprop,nwaq_degra,rank_degra,loitrac,
     & coef1trac)
!
!***********************************************************************
! WAQTEL   V8P2
!***********************************************************************
!
!brief    COMPUTES SOURCE TERMS FOR DEGRADATION LAWS PROCESSES
!
!history  C.-T. PHAM
!+        26/07/2020
!+        V8P2
!+        Creation from SOURCE_WAQ
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!| COEF1TRAC      |-->| COEFFICIENT 1 FOR LAW OF TRACERS DEGRADATION
!| HPROP          |-->| PROPAGATION DEPTH
!| LOITRAC        |-->| LAW OF TRACERS DEGRADATION
!| NPOIN          |-->| NUMBER OF NODES IN THE MESH
!| NWAQ_DEGRA     |-->| NUMBER OF TRACERS WITH A DEGRADATION LAW
!| RANK_DEGRA     |-->| GROUP TRACERS WITH A DEGRADATION LAW
!| TEXP           |-->| EXPLICIT SOURCE TERM
!| TIMP           |-->| IMPLICIT SOURCE TERM
!| TN             |-->| TRACERS AT TIME N
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      USE bief
      USE declarations_special
      IMPLICIT NONE
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER, INTENT(IN)             :: npoin
      TYPE(bief_obj), INTENT(IN)      :: tn
      TYPE(bief_obj), INTENT(INOUT)   :: texp,timp
      TYPE(bief_obj), INTENT(IN)      :: hprop
      INTEGER, INTENT(IN)             :: nwaq_degra
      INTEGER, INTENT(IN)             :: loitrac(*)
      INTEGER, INTENT(IN)             :: rank_degra(*)
      DOUBLE PRECISION, INTENT(IN)    :: coef1trac(*)
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER j,itrac
!
!-----------------------------------------------------------------------
!
      DO j = 1,nwaq_degra
        itrac = rank_degra(j)
        IF(loitrac(itrac).EQ.1) THEN
          CALL os('X=X+CY  ',x=timp%ADR(itrac)%P,
     &            y=hprop,c=-2.3d0/coef1trac(itrac)/3600.d0)
        ELSEIF(loitrac(itrac).EQ.2) THEN
          CALL os('X=X+CY  ',x=timp%ADR(itrac)%P,
     &            y=hprop,c=-coef1trac(itrac)/3600.d0)
        ELSEIF(loitrac(itrac).EQ.3) THEN
          CALL os('X=X+CY  ',x=timp%ADR(itrac)%P,
     &            y=hprop,c=-coef1trac(itrac)/86400.d0)
        ELSEIF(loitrac(itrac).EQ.4) THEN
          CALL user_calcs2d_degradation(npoin,tn,texp,timp,hprop,
     &              nwaq_degra,rank_degra,loitrac,coef1trac)
        ELSEIF(loitrac(itrac).GT.4) THEN
          WRITE(lu,21) loitrac(itrac),itrac
21    FORMAT(1x,'LOITRAC ',i4,' FOR TRACER ',i4,' NOT IMPLEMENTED YET')
          CALL plante(1)
          stop
        ENDIF
!
      ENDDO
!
!-----------------------------------------------------------------------
!
      RETURN
      END