calcs2d_biomass.f

Go to the documentation of this file.

!                     **************************
                      SUBROUTINE calcs2d_biomass
!                     **************************
!
     &  (npoin,wattemp,tn,texp,rayeff,hprop,t1,t2,t3,t4,t5,t6,debug)
!
!***********************************************************************
! WAQTEL   V8P1
!***********************************************************************
!
!brief    COMPUTES SOURCE TERMS FOR PHYTOPLANKTONIC BIOMASS WAQ PROCESS
!
!history  R. ATA
!+        21/09/2014
!+        V7P0
!+       CREATION
!
!history  S.E. BOURBAN (HRW)
!+        07/06/2017
!+        V7P3
!+        Indexing tracer (IND_*) to avoid conflicting naming convention
!+        between user defined tracers, water quality processes and
!+        ice processes. Introduction of the array RANK_*.
!
!history  S.E. BOURBAN (HRW)
!+        25/09/2017
!+        V7P3
!+        TEXP and TIMP are now additive to account for a variety of
!+        of sources / sinks on a given TRACER
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!| DEBUG          |-->| IF NE.0 THEN DEBUG MODE
!| HPROP          |-->| WATER DEPTH
!| NPOIN          |-->| TOTAL NUMBER OF MESH NODES
!| RAYEFF         |-->| EFFECT OF SUNSHINE ON ALGAE GROWTH
!| T1,..,T7       |<--| WORKING STRUCTURES
!| TN             |-->| TRACER STRUCUTRE
!| TEXP           |<--| EXPLICIT SOURCE TERMES
!| WATTEMP        |-->| WATER TEMPERATURE
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!-----------------------------------------------------------------------
!***********************************************************************
      USE bief
      USE interface_parallel
      USE declarations_waqtel,ONLY: cmax,ctoxic,ik,zsd,i0,mextinc,kp,kn,
     &  cmoralg,trespir,prophoc,dtp,pronitc,k360,k320,pernits,
     &  wpor,wnor,sectoday,kpe,
     &  ind_t,ind_phy,ind_no3,ind_po4,ind_nor,ind_por
      USE interface_waqtel, ex_calcs2d_biomass => calcs2d_biomass
!-----------------------------------------------------------------------
! .___________.____.____.______________________________________________.
! !    NOM    !TYPE!MODE!                   ROLE                       !
! !___________!____!____!______________________________________________!
! !  WPOR     ! R  !    ! VITESSE DE SEDIMENTATION DU PHOSPHORE ORGANIQ!
! !  WNOR     ! R  !    ! VITESSE DE SEDIMENTATION DE L AZOTE ORGANIQUE!
! !  CMAX     ! R  !    ! TAUX DE CROISSANCE ALGALE MAXIMUM A 20degC   !
! !  ZSD      ! R  !    ! PROFONDEUR DE SECCHI                         !
! !  KPE      ! R  !    ! COEF DE TURBIDITE VEGETALE                   !
! !  IK       ! R  !    ! PARAMETRE DE CALAGE DE LA FORMULE DE SMITH   !
! !  KP       ! R  !    ! CONSTANTE DE DEMI-SATURATION EN PHOSPHATE    !
! !  KN       ! R  !    ! CONSTANTE DE DEMI-SATURATION EN AZOTE        !
! !  ALPHA    ! R  !    ! COEF 1 DE TOXICITE DE L EAU POUR LES ALGUES  !
! !  ALPHA2   ! R  !    ! COEF 2 DE TOXICITE DE L EAU POUR LES ALGUES  !
! !  RP       ! R  !    ! TAUX DE RESP. DE LA BIOMASSE ALGALE A 20° C  !
! !  PROPHOC  ! R  !    ! PROP DE PHOSPHORE DANS LES CELLULES DU PHYTO !
! !  DTP      ! R  !    ! POURCENT DE PHOSPH DIRECT ASSIM DS PHY MORT  !
! !  K320     ! R  !    ! TAUX DE TRANSFORMATION DU POR EN PO4         !
! !  PRONITC  ! R  !    ! PROP D AZOTE DANS LES CELLULES DU PHYTO      !
! !  PERNITS  ! R  !    ! POURCENT D AZOTE DIRECT ASSIM DS PHY MORT    !
! !  K360     ! R  !    ! TAUX DE TRANSFORMATION DU NOR EN NO3         !
! !  M1       ! R  !    ! COEF 1 DE MORTALITE ALGALE A 20° C           !
! !  M2       ! R  !    ! COEF 2 DE MORTALITE ALGALE A 20° C           !
! !           !    !    !                                              !
! !  IF1      ! TR ! D  ! INDIC DE LECTURE DU FICHIER DES PARAMETRES   !
! !___________!____!____!______________________________________________!
!  MODE: -->(DONNEE NON MODIFIEE),<--(RESULTAT),<-->(DONNEE MODIFIEE)
!               (ENTREE)              (SORTIE)       (ENTREE/SORTIE)
!-----------------------------------------------------------------------
!***********************************************************************
      USE declarations_special
      IMPLICIT NONE
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER          , INTENT(IN   ) :: npoin,debug
      DOUBLE PRECISION , INTENT(IN   ) :: wattemp
      TYPE(bief_obj)   , INTENT(IN   ) :: tn,hprop
      TYPE(bief_obj)   , INTENT(INOUT) :: texp,rayeff,t1,t2,t3,t4,t5,t6
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
!
!     LOCAL VARIABLES
      DOUBLE PRECISION, PARAMETER :: eps=1.d-3
      DOUBLE PRECISION, PARAMETER :: unsurvingt=0.05d0
      DOUBLE PRECISION            :: g1
!
      IF(debug.GT.0)WRITE(lu,*)'IN BIOMASS, STEP 0'
!
!-----------------------------------------------------------------------
!
!    INITIALISATION
!
!     CP IS STORED IN T3
      CALL os( 'X=0     ',x=t3)
!     DP IS STORED IN T4
      CALL os( 'X=0     ',x=t4)
!     LNUT IS STORED IN T5
      CALL os( 'X=0     ',x=t5)
!
!     G1 IS STOCKED IN T6, WE TAKE INTO ACCOUNT VARIABLE TEMPERATURE
!
      g1 = wattemp/20.d0
      IF( ind_t.GT.0 )THEN
        CALL os('X=CY    ',x=t6,y=tn%ADR(ind_t)%P,c=unsurvingt)
      ELSE
        CALL os('X=C     ',x=t6,c=g1)
      ENDIF
!
      IF(debug.GT.0)WRITE(lu,*)'IN BIOMASS, STEP 1'
!
!     RAYEFF WITH SMITH FORMULA
!
      CALL ray_effect(zsd,tn%ADR(ind_phy)%P,npoin,mextinc,i0,ik,kpe,
     &                rayeff,hprop,t1,t2)
!
      IF(debug.GT.0)WRITE(lu,*)'IN BIOMASS, STEP 2'
!
!     COMPUTE LNUT
!
      CALL nuteff(t5%R,tn,npoin,ind_po4,ind_no3,kp,kn)
!
      IF(debug.GT.0)WRITE(lu,*)'IN BIOMASS, STEP 3'
!
!     RATE OF ALGAE GROWTH
!
      CALL algae_growth(t3%R,cmax,rayeff%R,t6,t5%R,ctoxic(1),npoin)
!
      IF(debug.GT.0)WRITE(lu,*)'IN BIOMASS, STEP 4'
!
!     RATE OF ALGAE DISAPPEARANCE
!
      CALL algae_death(t4%R,t1%R,cmoralg,tn%ADR(ind_phy)%P%R,trespir,t6,
     &                 ctoxic(2),npoin)
!
      IF(debug.GT.0)WRITE(lu,*)'IN BIOMASS, STEP 5'
!
!-----------------------------------------------------------------------
!
!     LET'S NOW COMPUTE SOURCE TERMS
!
!     FIRST TRACER [PHY] (IND_PHY)
!
      CALL os( 'X=Y-Z   ' ,x=t1                 ,y=t3,z=t4)
!      CALL OS( 'X=YZ    ' ,X=TEXP%ADR(IND_PHY)%P,Y=T1,
!     &                     Z=TN%ADR(IND_PHY)%P)
      CALL os( 'X=X+CYZ ' ,x=texp%ADR(ind_phy)%P,y=t1,
     &                     z=tn%ADR(ind_phy)%P,c=sectoday)
!
      IF(debug.GT.0)WRITE(lu,*)'IN BIOMASS, STEP 6'
!
!     SECOND TRACER [PO4] (IND_PO4)
!
      CALL os( 'X=CY    ' ,x=t1,y=t4                    ,c=dtp      )
      CALL os( 'X=X-Y   ' ,x=t1,y=t3                                )
      CALL os( 'X=CXY   ' ,x=t1,y=tn%ADR(ind_phy)%P     ,c=prophoc  )
      CALL os( 'X=CYZ   ' ,x=t2,y=tn%ADR(ind_por)%P,z=t6,c=k320     )
!
!      CALL OS( 'X=Y+Z   ' ,X=TEXP%ADR(IND_PO4)%P,Y=T1,Z=T2          )
      CALL os( 'X=X+Y   ' ,x=t1,y=t2                                )
      CALL os( 'X=X+CY  ' ,x=texp%ADR(ind_po4)%P,y=t1   ,c=sectoday )
!
      IF(debug.GT.0)WRITE(lu,*)'IN BIOMASS, STEP 7'
!
!     THIRD TRACER [POR] (IND_POR)
!
      g1=prophoc*(1.d0-dtp)
      CALL os( 'X=CYZ   ' ,x=t1,y=t4,z=tn%ADR(ind_phy)%P,c=g1       )
      CALL os( 'X=X-Y   ' ,x=t1,y=t2                                )
      CALL ovd('X=CY/Z  ' ,t2%R,tn%ADR(ind_por)%P%R,hprop%R,wpor,
     &          npoin ,2,0.d0,eps                                   )
!      CALL OS( 'X=Y-Z   ' ,X=TEXP%ADR(IND_POR)%P,Y=T1,Z=T2          )
      CALL os( 'X=X-Y   ' ,x=t1,y=t2                                )
      CALL os( 'X=X+CY  ' ,x=texp%ADR(ind_por)%P,y=t1   ,c=sectoday )
!
      IF(debug.GT.0)WRITE(lu,*)'IN BIOMASS, STEP 8'
!
!     FOURTH TRACER [NO3] (IND_NO3)
!
      CALL os( 'X=CY    ' ,x=t1,y=t4                      ,c=pernits)
      CALL os( 'X=C(Y-Z)' ,x=t1,y=t1                 ,z=t3,c=pronitc)
      CALL os( 'X=XY    ' ,x=t1,y=tn%ADR(ind_phy)%P                 )
      CALL os( 'X=CYZ   ' ,x=t2,y=tn%ADR(ind_nor)%P  ,z=t6,c=k360   )
!
!      CALL OS( 'X=Y+Z   ' ,X=TEXP%ADR(IND_NO3)%P,Y=T1,Z=T2          )
      CALL os( 'X=X+Y   ' ,x=t1,y=t2                                )
      CALL os( 'X=X+CY  ' ,x=texp%ADR(ind_no3)%P,y=t1   ,c=sectoday )
!
      IF(debug.GT.0)WRITE(lu,*)'IN BIOMASS, STEP 9'
!
!     FIFTH TRACER [NOR] (IND_NOR)
!
      g1=pronitc*(1.d0-pernits)
      CALL os( 'X=CYZ   ' ,x=t1,y=t4,z=tn%ADR(ind_phy)%P,c=g1       )
      CALL os( 'X=X-Y   ' ,x=t1,y=t2                                )
      CALL ovd('X=CY/Z  ' ,t2%R,tn%ADR(ind_nor)%P%R,hprop%R,wnor,
     &         npoin ,2,0.d0,eps )
!
!      CALL OS( 'X=Y-Z   ' ,X=TEXP%ADR(IND_NOR)%P,Y=T1,Z=T2          )
      CALL os( 'X=X-Y   ' ,x=t1,y=t2                                )
      CALL os( 'X=X+CY  ' ,x=texp%ADR(ind_nor)%P,y=t1   ,c=sectoday )
!
      IF(debug.GT.0)WRITE(lu,*)'IN BIOMASS, STEP 10'
!
!-----------------------------------------------------------------------
!
      RETURN
      END