bornes.f

Go to the documentation of this file.

!                   *****************
                    SUBROUTINE bornes
!                   *****************
!
     &( b     , n     , a     , xm    , x0    , x1    )
!
!***********************************************************************
! TOMAWAC   V6P1                                   08/06/2011
!***********************************************************************
!
!brief    COMPUTES THE INTEGRATION BOUNDS FOR THE INTEGRATION
!+                OF  THE FUNCTION "FONCRO", USING GAUSS QUADRATURES.
!
!history  F. BECQ (EDF/DER/LNH)
!+        26/03/96
!+        V1P1
!+
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        13/07/2010
!+        V6P0
!+   Translation of French comments within the FORTRAN sources into
!+   English comments
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        21/08/2010
!+        V6P0
!+   Creation of DOXYGEN tags for automated documentation and
!+   cross-referencing of the FORTRAN sources
!
!history  G.MATTAROLO (EDF - LNHE)
!+        08/06/2011
!+        V6P1
!+   Translation of French names of the variables in argument
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!| A              |-->| PARAMETER A OF THE FUNCTION TO INTGRATE
!| B              |-->| PARAMETER B OF THE FUNCTION TO INTGRATE
!| N              |-->| EXPONENT N OF THE FUNCTION TO INTGRATE
!| X0             |<--| LOWER BOUND OF THE INTERVAL
!| X1             |<--| UPPER BOUND OF THE INTERVAL
!| XM             |-->| PARAMETER XM OF THE FUNCTION TO INTGRATE
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      USE declarations_special
      USE interface_tomawac, ex_bornes => bornes
      IMPLICIT NONE
!
!
!     VARIABLES IN ARGUMENT
!     """""""""""""""""""""
      INTEGER, INTENT(IN)             :: N
      DOUBLE PRECISION, INTENT(IN)    :: B, A, XM
      DOUBLE PRECISION, INTENT(INOUT) :: X0, X1
!
!     LOCAL VARIABLES
!     """"""""""""""""""
      INTEGER  I0    , I1    , II    , JJ    , IMAX  , INP
      DOUBLE PRECISION X(11) , Y(11) , EPS   , EPS1  , DX
!
!.....EXTERNAL FUNCTIONS
!     """"""""""""""""""
!      DOUBLE PRECISION  FONCRO
!      EXTERNAL          FONCRO
!
!
      i1  = 11
      i0  = 1
      x(i0)= 0.d0
      x(i1)= 20.d0
      y(1) = 0.d0
      eps1 = 0.01d0
      eps  = 0.0001d0
      inp  = 0
!
      DO ii=1,20
        dx = (x(i1)-x(i0))/10.d0
        x(1) = x(i0)
        imax = 0
        i0   = 1
        i1   = 11
        DO jj=2,11
          x(jj)=x(jj-1)+dx
          y(jj)=foncro(x(jj),b,n,a,xm)
          IF(y(jj).EQ.0.d0.AND.jj.EQ.2.AND.inp.EQ.0d0) THEN
            x(i1) = x(i1)/10.d0
            inp   = 1
            GOTO 10
          END IF
          IF(y(jj).LT.y(jj-1)) THEN
            IF(imax.EQ.0) THEN
              imax = jj-1
              eps  = eps1*y(imax)
            END IF
            IF (y(jj).LT.eps) THEN
              i1 = jj
              EXIT
            END IF
          ELSEIF(imax.EQ.0.AND.y(jj).LT.eps.AND.jj.NE.2) THEN
            i0 = jj
          END IF
        END DO
        IF((i1-i0).GT.2) EXIT
   10   CONTINUE
      ENDDO ! II
!
      x0 = x(i0)
      x1 = x(i1)
!
      RETURN
      END