bief_valida.f

Go to the documentation of this file.

!                   **********************
                    SUBROUTINE bief_valida
!                   **********************
!
     &(varref,textref,uref,refformat,varres,textres,ures,resformat,
     & maxtab,np,it,maxit,acomparer)
!
!***********************************************************************
! BIEF   V6P3                                   21/08/2010
!***********************************************************************
!
!brief    VALIDATES THE RESULTS AGAINST AN ANALYTICAL SOLUTION
!+                OR AGAINST RESULTS IN THE COMPUTATION REFERENCE FILE.
!
!note     THE LAST TIMESTEP ONLY IS COMPARED.
!note  EXCEPT FOR THE BOTTOM, ASSUMES THAT THE REFERENCE
!+         FILE DOES HOLD THE VARIABLES TO BE COMPARED.
!
!warning  THIS SUBROUTINE MUST BE MODIFIED ACCORDING TO EACH
!+            PARTICULAR CASE
!
!history  J-M HERVOUET (LNHE)
!+        05/08/2009
!+        V6P0
!+
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        13/07/2010
!+        V6P0
!+   Translation of French comments within the FORTRAN sources into
!+   English comments
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        21/08/2010
!+        V6P0
!+   Creation of DOXYGEN tags for automated documentation and
!+   cross-referencing of the FORTRAN sources
!
!history  J-M HERVOUET (LNHE)
!+        05/08/2009
!+        V6P3
!+   Name of code now printed in the listing.
!
!history Y AUDOUIN (LNHE)
!+       25/05/2015
!+       V7P0
!+       Modification to comply with the hermes module
!
!history  J,RIEHME (ADJOINTWARE)
!+        November 2016
!+        V7P2
!+   Replaced EXTERNAL statements to parallel functions / subroutines
!+   by the INTERFACE_PARALLEL
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!| ACOMPARER      |-->| INDICATES WHICH VARIABLE TO COMPARE
!| IT             |-->| TIME STEP NUMBER
!| MAXIT          |-->| MAXIMUM NUMBER OF ITERATIONS
!| MAXTAB         |-->| TOTAL NUMBER OF VARIABLES
!| NP             |-->| NUMBER OF POINTS TO BE CHECKED
!| REFFORMAT      |-->| FORMAT OF REFERENCE FILE
!| RESFORMAT      |-->| FORMAT OF RESULTS FILE
!| TEXTREF        |-->| NAMES & UNITS OF VARIABLES IN THE REFERENCE FILE
!| TEXTRES        |-->| NAMES & UNITS OF VARIABLES IN THE RESULTS FILE
!| UREF           |-->| LOGICAL UNIT OF REFERENCE FILE
!| URES           |-->| LOGICAL UNIT OF RESULTS FILE
!| VARREF         |-->| BLOCK OF VARIABLES IN REFERENCE FILE
!| VARRES         |-->| BLOCK OF VARIABLES IN RESULTS FILE
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      USE bief, ex_bief_valida => bief_valida
      USE bief_def
      USE declarations_telemac
!
      USE declarations_special
      USE interface_parallel, ONLY : p_max
      IMPLICIT NONE
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER, INTENT(IN) :: NP,MAXTAB,IT,MAXIT,URES,UREF
      INTEGER, INTENT(IN) :: ACOMPARER(maxtab)
!
      CHARACTER(LEN=32), INTENT(IN) :: TEXTREF(maxtab),TEXTRES(maxtab)
!
      TYPE(bief_obj), INTENT(INOUT) :: VARREF,VARRES
      CHARACTER(LEN=*), INTENT(IN)  :: REFFORMAT,RESFORMAT
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER IVAR,I,IREF,IRES,IERMAX
!
      DOUBLE PRECISION TIMEREF,TIMERES,ERMAX,ERR
!
!-----------------------------------------------------------------------
!
      INTEGER FINDREF(500),FINDRES(500)
      IF(maxtab.GT.500) THEN
        WRITE(lu,*) 'WRONG SIZE OF FINDREF AND FINDRES IN BIEF_VALIDA'
        CALL plante(1)
        stop
      ENDIF
!
!-----------------------------------------------------------------------
!
      IF(it.EQ.maxit) THEN
!
!  CALLS SUITE TO READ THE REFERENCE FILE
!
      WRITE(lu,11) namecode
      CALL read_dataset(refformat,uref,varref,np,iref,timeref,
     &                  textref,findref,acomparer,.true.,.true.,maxtab)
!
!  CALLS SUITE TO READ THE RESULTS FILE
!
      WRITE(lu,13)
      CALL read_dataset(resformat,ures,varres,np,ires,timeres,
     &                  textres,findres,acomparer,.true.,.true.,maxtab)
!
!-----------------------------------------------------------------------
!
      WRITE(lu,15)
!
      IF(abs(timeres-timeref)/max(timeref,1.d-4).GT.1.d-2) THEN
        WRITE(lu,17)
      ENDIF
      IF(ires.NE.iref) THEN
        WRITE(lu,19)
      ENDIF
!
!-----------------------------------------------------------------------
!
!     LOOP ON THE VARIABLES TO COMPARE
!
      DO ivar=1,min(maxtab,varref%N,varres%N)
!
        IF(acomparer(ivar).EQ.1) THEN
!
!       COMPARES THE VARIABLE IVAR
!
          IF(findref(ivar).EQ.1.AND.findres(ivar).EQ.1) THEN
!
            ermax = 0.d0
            iermax = 1
            DO i = 1 , np
              err=abs(varref%ADR(ivar)%P%R(i)-varres%ADR(ivar)%P%R(i))
              IF(err.GT.ermax) THEN
                ermax=err
                iermax=i
              ENDIF
            ENDDO
!
            IF(ncsize.GT.1) ermax=p_max(ermax)
            WRITE(lu,61) textres(ivar)(1:16),ermax
!
          ELSEIF(findref(ivar).EQ.1) THEN
!
            WRITE(lu,71) textres(ivar)(1:16)
!
          ENDIF
!
        ENDIF
!
      ENDDO
!
      WRITE(lu,51)
!
      ENDIF
!
!-----------------------------------------------------------------------
!
11    FORMAT(1x,////,1x,80('='),/,
     &       25x,' VALIDATION PROCEDURE OF ',a24,/,
     &       1x,80('-'),//,
     &       1x,' 1) READING THE REFERENCE FILE :',/,
     &       1x,' ------------------------------',/)
13    FORMAT(1x,///,
     &       1x,' 2) READING THE RESULTS FILE :',/,
     &       1x,' --------------------------------',/)
15    FORMAT(1x,///,
     &       1x,' 3) COMPARISON:',/,
     &       1x,' --------------',/)
17    FORMAT(1x,///,
     &       1x,' BEWARE: TIMES ARE DIFFERENT',/,
     &       1x,' ---------------------------',/)
19    FORMAT(1x,///,
     &       1x,' BEWARE: RECORD NUMBERS ARE DIFFERENT',/,
     &       1x,' ------------------------------------',/)
!
51    FORMAT(1x,80('-'),/,23x,'END OF VALIDATION REPORT',/,
     &       1x,80('='),////)
!
61    FORMAT(1x,'VARIABLE: ' ,a16,'  DIFFERENCE: ',g16.7,/)
!
71    FORMAT(1x,'VARIABLE: ' ,a16,'  NOT FOUND'  ,/)
!
!-----------------------------------------------------------------------
!
      RETURN
      END