bief_open_files.f

Go to the documentation of this file.

!                   **************************
                    SUBROUTINE bief_open_files
!                   **************************
!
     &(code,files,nfiles,path,ncar,icode,fullname)
!
!***********************************************************************
! BIEF   V7P1
!***********************************************************************
!
!brief    OPENS FILES DECLARED IN THE STEERING FILE.
!
!note     STEERING AND DICTIONARY FILES ARE OPENED AND CLOSED
!+         IN LECDON
!
!history  J-M HERVOUET (LNHE)
!+        12/10/2009
!+        V6P0
!+
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        13/07/2010
!+        V6P0
!+   Translation of French comments within the FORTRAN sources into
!+   English comments
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        21/08/2010
!+        V6P0
!+   Creation of DOXYGEN tags for automated documentation and
!+   cross-referencing of the FORTRAN sources
!
!history  J-M HERVOUET (EDF R&D, LNHE)
!+        27/11/2013
!+        V6P3
!+   Opening by all processors of ACTION='WRITE' file precluded. In this
!+   case only the processor 0 will do it.
!
!history  J-M HERVOUET (EDF R&D, LNHE)
!+        26/12/2013
!+        V7P0
!+   Checking the declared format when possible : case of a SERAFIN file
!+   in READ mode.
!
!history Y AUDOUIN (LNHE)
!+       25/05/2015
!+       V7P0
!+       Modification to comply with the hermes module
!
!history  J. GRASSET (Daresbury Lab & EDF)
!+        01/05/2018
!+        Add code for managing concatenated mesh
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!| CODE           |-->| NAME OF CALLING PROGRAMME
!| FILES          |-->| STRUCTURES OF CODE FILES
!| ICODE          |---| NUMERO DU CODE EN CAS DE COUPLAGE
!| NCAR           |-->| NUMBER OF CHARACTERS IN THE PATH
!| NFILES         |-->| NUMBER OF FILES
!| PATH           |-->| FULL NAME OF THE PATH WHERE THE CASE IS
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      USE bief, ex_bief_open_files => bief_open_files
      USE declarations_telemac
      USE interface_hermes
!
      USE declarations_special
      IMPLICIT NONE
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER           , INTENT(IN)    :: NFILES
      CHARACTER(LEN=24) , INTENT(IN)    :: CODE
      TYPE(bief_file)   , INTENT(INOUT) :: FILES(nfiles)
      CHARACTER(LEN=PATH_LEN), INTENT(IN)    :: PATH
      INTEGER           , INTENT(IN)    :: NCAR,ICODE
      LOGICAL           , INTENT(IN)    :: FULLNAME
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER I, II, ICLI, IERR
      LOGICAL :: IS_CONCATENATE, RDONLY_PARAL
!
      CHARACTER(LEN=11) :: FORME,EXTENS
      CHARACTER(LEN=300) :: FILE_NAME
      CHARACTER(LEN=300) :: CLI_NAME
      EXTERNAL extens
!
!-----------------------------------------------------------------------
!
!     MESSAGE
!
      WRITE(lu,*) 'OPENING FILES FOR ',code
!
!
!     DECODES THE SUBMIT STRING FOR THE FILES IN THE STEERING FILE
!
      DO i=1,nfiles
!
        is_concatenate=.false.
        rdonly_paral=.false.
        IF(files(i)%NAME(1:1).NE.' ') THEN
!
          WRITE(lu,*) 'OPENING: ', trim(files(i)%TELNAME), '-',
     &                trim(files(i)%NAME)
!         GET LOGICAL UNIT
          CALL get_free_id(files(i)%LU)
!
          IF(files(i)%BINASC.EQ.'ASC') THEN
            forme='FORMATTED  '
          ELSE
            forme='UNFORMATTED'
          ENDIF
!
!         OPENS THE FILE
          ! If fullname name is true we use the real name of the file not the temporary foldare name
          IF(fullname) THEN
            file_name = files(i)%NAME
          ELSE
            file_name = path(1:ncar)//trim(files(i)%TELNAME)
          ENDIF
!
          ! Boundary file will be opened by the hermes module
          IF(files(i)%TYPE.EQ.'CONLIM') cycle
!
          IF((files(i)%FMT(1:7).EQ.'SERAFIN')
     &       .OR.(files(i)%FMT.EQ.'MED     ')) THEN
            ! Get the boundary confitions file
            icli = 0
            IF(files(i)%ACTION.EQ.'READ     ') THEN
              !CONCATENATE FILES EXISTS ONLY IN READONLY MODE
              IF(partel_concat)is_concatenate = .true.
              !IF IT'S A PARAL FILE IN READ ONLY MODE, THEN THERE IS
              !ONLY A SINGLE FILE OPENED BY ALL THE PROCESSES
              IF(files(i)%TYPE(1:5).EQ.'PARAL')THEN
                rdonly_paral = .true.
                is_concatenate = .false.
              ENDIF
              DO ii=1,nfiles
                IF(files(ii)%NAME(1:1).NE.' ') THEN
                  IF(files(ii)%TYPE(1:6).EQ.'CONLIM') THEN
                    icli = ii
                    EXIT
                  ENDIF
                ENDIF
              ENDDO
              IF(icli.EQ.0) THEN
                WRITE(lu,*) 'NO BOUNDARY CONDITIONS FILE'
              ENDIF
            ENDIF
!
            ! Rename file_name and cli_name
            IF(fullname) THEN
              file_name = path(1:ncar)//trim(files(i)%NAME)
              IF(icli.NE.0) THEN
                cli_name = path(1:ncar)//trim(files(icli)%NAME)
              ENDIF
            ELSE
              file_name = path(1:ncar)//trim(files(i)%TELNAME)
              IF(icli.NE.0) THEN
                cli_name = path(1:ncar)//trim(files(icli)%TELNAME)
              ENDIF
            ENDIF

            IF((ncsize>1).AND.(files(i)%TYPE(1:4)/='SCAL')) THEN
              IF(is_concatenate)THEN
                file_name=trim(file_name)//'-CONCAT'
                cli_name=trim(cli_name)//'-CONCAT'
              ELSE IF(.NOT. rdonly_paral)THEN
                file_name=trim(file_name)//extens(ncsize-1,ipid)
                cli_name=trim(cli_name)//extens(ncsize-1,ipid)
              ELSE IF(rdonly_paral)THEN
                file_name=trim(file_name)
                cli_name=trim(cli_name)
              ENDIF
            ENDIF

            IF(files(i)%TYPE(1:4).EQ.'SCAL') THEN
              ! If the file is a scalar type on the processor zero is opning it
              ! And it a read or readwrite file
              IF(ipid.EQ.0.OR.files(i)%ACTION(1:4).EQ.'READ') THEN
                CALL open_mesh(files(i)%FMT, trim(file_name),
     &                         files(i)%LU, files(i)%ACTION, ierr)
                CALL check_call(ierr,'BIEF_OPEN_FILES:OPEN_MESH')
                IF(icli.NE.0) THEN
                  CALL open_bnd(files(i)%FMT, trim(cli_name),
     &                          files(i)%LU, files(icli)%ACTION, ierr)
                  CALL check_call(ierr,'BIEF_OPEN_FILES:OPEN_BND')
                ENDIF
              ENDIF
            ELSE
              IF(is_concatenate)THEN
                CALL open_mesh(files(i)%FMT,trim(file_name),files(i)%LU,
     &                         files(i)%ACTION, ierr, ipid+1)
              ELSE
                CALL open_mesh(files(i)%FMT,trim(file_name),files(i)%LU,
     &                         files(i)%ACTION, ierr)
              ENDIF
              CALL check_call(ierr,'BIEF_OPEN_FILES:OPEN_MESH')
              IF(icli.NE.0) THEN
                IF(is_concatenate)THEN
                  CALL open_bnd(files(i)%FMT, trim(cli_name),
     &                          files(i)%LU, files(icli)%ACTION, ierr,
     &                          ipid+1)
                ELSE
                  CALL open_bnd(files(i)%FMT, trim(cli_name),
     &                          files(i)%LU, files(icli)%ACTION, ierr)
                ENDIF
                CALL check_call(ierr,'BIEF_OPEN_FILES:OPEN_BND')
              ENDIF
            ENDIF
            IF(ierr.NE.0) THEN
              WRITE(lu,*) 'ERROR WHILE OPENING: ', trim(file_name)
              WRITE(lu,*) 'AND: ', trim(cli_name)
              WRITE(lu,*) 'IN ',files(i)%FMT,' FORMAT '
              WRITE(lu,*) 'IN ',files(i)%ACTION,' MODE'
              WRITE(lu,*) 'ERROR ',ierr
              CALL plante(1)
              stop
            ENDIF
!
          ELSE
!
            IF(ncsize.LE.1) THEN
!             SCALAR
              OPEN(files(i)%LU,file=file_name,
     &             form=forme,action=files(i)%ACTION)
            ELSE
!             PARALLEL, FILE TYPE: SCAL
!             ALL PROCESSORS CANNOT OPEN THE SAME FILE FOR WRITING
!             IN THIS CASE, ONLY PROCESSOR 0 MAY OPEN AND WRITE
              IF(files(i)%TYPE(1:4).EQ.'SCAL') THEN
                IF(ipid.EQ.0.OR.files(i)%ACTION(1:5).NE.'WRITE') THEN
                  OPEN(files(i)%LU,
     &                 file=file_name,
     &                 form=forme,action=files(i)%ACTION)
                ENDIF
!             PARALLEL, OTHER FILE TYPE
              ELSE IF(files(i)%TYPE(1:5).EQ.'PARAL' .AND.
     &                files(i)%ACTION .EQ. 'READ     ')THEN
                OPEN(files(i)%LU,
     &               file=trim(file_name),
     &               form=forme,action=files(i)%ACTION)
              ELSE
                OPEN(files(i)%LU,
     &               file=trim(file_name)
     &               //extens(ncsize-1,ipid),
     &               form=forme,action=files(i)%ACTION)
              ENDIF
            ENDIF
!
          ENDIF
!
        ENDIF
!
      ENDDO
!
!     SETS AND STORES THE CODE NAME
!
      namecode = code
      nnamecode(icode) = code
!
!
!-----------------------------------------------------------------------
!
      RETURN
      END