bief_dim1_ext.f

Go to the documentation of this file.

!                   ******************************
                    INTEGER FUNCTION bief_dim1_ext
!                   ******************************
!
     &(ielm1,ielm2,sto,typext,mesh)
!
!***********************************************************************
! BIEF   V6P1                                   21/08/2010
!***********************************************************************
!
!brief    GIVES THE FIRST DIMENSION OF A MATRICE'S EXTRA-DIAGONAL
!+                TERMS.
!
!history  J-M HERVOUET (LNH)
!+        05/02/2010
!+        V6P0
!+
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        13/07/2010
!+        V6P0
!+   Translation of French comments within the FORTRAN sources into
!+   English comments
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        21/08/2010
!+        V6P0
!+   Creation of DOXYGEN tags for automated documentation and
!+   cross-referencing of the FORTRAN sources
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!| IELM1          |-->| TYPE OF LINE ELEMENT
!| IELM2          |-->| TYPE OF COLUMN ELEMENT
!| MESH           |-->| MESH STRUCTURE
!| STO            |-->| TYPE OF STORAGE
!| TYPEXT         |-->| TYPE OF OFF-DIAGONAL TERMS
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      USE bief, ex_bief_dim1_ext => bief_dim1_ext
!
      USE declarations_special
      IMPLICIT NONE
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER         , INTENT(IN) :: IELM1,IELM2,STO
      CHARACTER(LEN=1), INTENT(IN) :: TYPEXT
      TYPE(bief_mesh) , INTENT(IN) :: MESH
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER IELMX,N
!
!-----------------------------------------------------------------------
!
      ielmx = 10*(ielm1/10)
!
      IF(typext.EQ.'0') THEN
!
!       NOT 0 TO ENABLE BOUND CHECKING
        bief_dim1_ext = 1
!
      ELSEIF(sto.EQ.1) THEN
!
!       CLASSICAL EBE STORAGE
!
        bief_dim1_ext =bief_nbmpts(ielmx,mesh)
!
      ELSEIF(sto.EQ.3) THEN
!
!       EDGE-BASED STORAGE
!
        IF(typext.EQ.'S') THEN
          bief_dim1_ext=bief_nbseg(ielm1,mesh)
        ELSE
          bief_dim1_ext=bief_nbseg(ielm1,mesh)+bief_nbseg(ielm2,mesh)
          n=max(bief_nbpel(ielm1,mesh),bief_nbpel(ielm2,mesh))
     &     -min(bief_nbpel(ielm1,mesh),bief_nbpel(ielm2,mesh))
          IF(n.GE.2) THEN
!           SOME SEGMENTS LINK ONLY E.G. QUADRATIC POINTS AND
!           WILL NOT BE CONSIDERED IN A RECTANGULAR MATRIX
!           THIS IS THE CASE WITH 3 SEGMENTS IN QUADRATIC TRIANGLE
            bief_dim1_ext=bief_dim1_ext
     &                   -n*(n-1)*bief_nbmpts(ielmx,mesh)/2
          ENDIF
        ENDIF
!
      ELSE
!
        WRITE(lu,101) sto
101     FORMAT(1x,'BIEF_DIM1_EXT : UNKNOWN TYPE OF STORAGE: ',1i6)
        CALL plante(1)
        stop
!
      ENDIF
!
!-----------------------------------------------------------------------
!
      RETURN
      END