bief_desimp.f

Go to the documentation of this file.

!                   **********************
                    SUBROUTINE bief_desimp
!                   **********************
!
     &(format_res,varsor,n,nres,at,lt,lisprd,leoprd,
     & sorleo,sorimp,maxvar,texte,ptinig,ptinil,mesh,
     & iimp,ileo,compgraph)
!
!***********************************************************************
! BIEF   V7P1
!***********************************************************************
!
!brief    WRITES TO RESULT OR LISTING FILE.
!
!history  J-M HERVOUET (LNHE)
!+        01/04/2009
!+        V6P0
!+
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        13/07/2010
!+        V6P0
!+   Translation of French comments within the FORTRAN sources into
!+   English comments
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        21/08/2010
!+        V6P0
!+   Creation of DOXYGEN tags for automated documentation and
!+   cross-referencing of the FORTRAN sources
!
!history  V. STOBIAC
!+        10/12/2014
!+        V7P0
!+   Add update of mesh coordinates for moving mesh
!
!history Y AUDOUIN (LNHE)
!+       25/05/2015
!+       V7P0
!+       Modification to comply with the hermes module
!
!history  R. ATA (LNHE)
!+       11/01/2015
!+       V7P2
!+       adaptation for fv (leo, imp and compgraph added as
!+        optional arguments)
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!| FORMAT_RES     |-->| FORMAT OF RESULT FILE
!| LEOPRD         |-->| GRAPHIC PRINTOUT PERIOD
!| LISPRD         |-->| LISTING PRINTOUT PERIOD
!| MAXVAR         |-->| MAXIMUM OF VARIABLES IN THE FILE
!| N              |-->| NUMBER OF POINTS IN THE MESH
!| NRES           |-->| LOGICAL UNIT OF THE RESULTS FILE
!| PTINIG         |-->| NUMBER OF FIRST TIME STEP FOR GRAPHIC PRINTOUTS
!| PTINIL         |-->| NUMBER OF FIRST TIME STEP FOR LISTING PRINTOUTS
!| SORIMP         |-->| ARRAY OF LOGICAL SAYING IF VARIABLES MUST BE PUT
!|                |   | IN THE LISTING
!| SORLEO         |-->| ARRAY OF LOGICAL SAYING IF VARIABLES MUST BE PUT
!|                |   | IN THE RESULTS FILE
!| TEXTE          |-->| NAMES AND UNITS OF VARIABLES
!| VARSOR         |-->| BLOCK WITH VARIABLES TO BE PRINTED OR COPIED
!| MESH (OPTIONAL)|-->| MESH STRUCTURE
!| ILEO & IIMP)   |-->| LOGICAL FOR LISTING AND GRAPHICAL OUTPUTS
!| COMPGRAPH      |-->| COUNTER FOR FV GRAPHICAL OUTPUTS
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      USE bief, ex_bief_desimp => bief_desimp
      USE interface_hermes
!
      USE declarations_special
      IMPLICIT NONE
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      TYPE(bief_obj)   , INTENT(IN) :: VARSOR
      CHARACTER(LEN=8) , INTENT(IN) :: FORMAT_RES
      INTEGER          , INTENT(IN) :: NRES,LT,LISPRD,LEOPRD
      INTEGER          , INTENT(IN) :: PTINIG,PTINIL,N
      INTEGER          , INTENT(IN) :: MAXVAR
      DOUBLE PRECISION , INTENT(IN) :: AT
      CHARACTER(LEN=32), INTENT(IN) :: TEXTE(*)
      LOGICAL          , INTENT(IN) :: SORLEO(maxvar),SORIMP(maxvar)
      TYPE(bief_mesh)  , INTENT(IN), OPTIONAL :: MESH
      LOGICAL          , INTENT(IN), OPTIONAL :: IIMP,ILEO
      INTEGER          , INTENT(IN), OPTIONAL :: COMPGRAPH
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER LTT,K
!
      LOGICAL LEO,IMP
!
!-----------------------------------------------------------------------
!
! LOGICAL THAT DEFINE THE OUTPUTS
!
      imp=.false.
      leo=.false.
      ltt=(lt/lisprd)*lisprd
      IF(lt.EQ.ltt.AND.lt.GE.ptinil) imp=.true.
      ltt=(lt/leoprd)*leoprd
      IF(lt.EQ.ltt.AND.lt.GE.ptinig) leo=.true.
      IF(lt.EQ.0) leo=.true.
      IF(PRESENT(iimp))imp=iimp
      IF(PRESENT(ileo))leo=ileo
!
!-----------------------------------------------------------------------
!
      IF(leo) THEN
!
!       COUNTERS FOR TELEMAC2D
        IF(PRESENT(compgraph))THEN
          ltt=compgraph
        ELSE
!       COUNTERS FOR OTHER CODES
          ltt = (lt-ptinig)/leoprd
        ! In case the starting point is not at lt.eq.0 but later
        !  we still write the timestep 0 so we need to increment LTT
          IF(ptinig.NE.0) ltt = ltt + 1
          IF(lt.EQ.0) ltt = 0
        ENDIF
!
        IF(PRESENT(mesh)) THEN
          CALL write_data(format_res,nres,maxvar,at,ltt,sorleo,
     &                    texte,varsor,n,mesh)
        ELSE
          CALL write_data(format_res,nres,maxvar,at,ltt,sorleo,
     &                    texte,varsor,n)
        ENDIF
      ENDIF
!
! TO LISTING FILE
!
      IF(imp) THEN
        DO k=1,maxvar
          IF(sorimp(k)) THEN
            IF(ASSOCIATED(varsor%ADR(k)%P%R)) THEN
              CALL impvec(varsor%ADR(k)%P%R,texte(k),n)
            ELSE
              WRITE(lu,*) 'DESIMP: VARIABLE NUMBER: ',k
              WRITE(lu,*) '        NOT OR NOT WELL ALLOCATED'
              WRITE(lu,*) '        OR POINTER NOT ASSOCIATED '
!             CALL PLANTE(1)
!             STOP
            ENDIF
          ENDIF
        ENDDO
      ENDIF
!
!=======================================================================
!
      RETURN
      END