bief_close_files.f

Go to the documentation of this file.

!                   ***************************
                    SUBROUTINE bief_close_files
!                   ***************************
!
     &(files,nfiles,pexit)
!
!***********************************************************************
! BIEF   V6P1                                   21/08/2010
!***********************************************************************
!
!brief
!
!history  J-M HERVOUET (LNHE)
!+        01/04/2009
!+        V6P0
!+
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        13/07/2010
!+        V6P0
!+   Translation of French comments within the FORTRAN sources into
!+   English comments
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        21/08/2010
!+        V6P0
!+   Creation of DOXYGEN tags for automated documentation and
!+   cross-referencing of the FORTRAN sources
!
!history Y AUDOUIN (LNHE)
!+       25/05/2015
!+       V7P0
!+       Modification to comply with the hermes module
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!| FILES          |-->| ARRAY OF BIEF_FILE STRUCTURES
!| NFILES         |-->| TOTAL NUMBER OF FILES
!| PEXIT          |-->| LOGICAL, IF YES, P_EXIT WILL BE CALLED
!|                |   | TO STOP PARALLELISM
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      USE bief, ex_bief_close_files => bief_close_files
!
      USE declarations_telemac
      USE interface_hermes
!
      USE declarations_special
      IMPLICIT NONE
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER          , INTENT(IN)     :: NFILES
      LOGICAL, INTENT(IN)               :: PEXIT
      TYPE(bief_file)   , INTENT(INOUT) :: FILES(nfiles)
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER I,IERR
!
!-----------------------------------------------------------------------
!
      DO i=1,nfiles
!
        IF(files(i)%NAME(1:1).NE.' ') THEN
!
!         CLOSES THE FILE
!
          IF(files(i)%TYPE.EQ.'CONLIM') cycle
          IF((files(i)%FMT(1:7).EQ.'SERAFIN')
     &       .OR.(files(i)%FMT.EQ.'MED     ')) THEN
            IF(files(i)%TYPE(1:4).EQ.'SCAL') THEN
              IF(ipid.EQ.0.OR.files(i)%ACTION(1:4).EQ.'READ') THEN
                CALL close_bnd(files(i)%FMT, files(i)%LU, ierr)
                CALL check_call(ierr,'BIEF_CLOSE_FILE:CLOSE_BND')
                CALL close_mesh(files(i)%FMT, files(i)%LU, ierr)
                CALL check_call(ierr,'BIEF_CLOSE_FILE:CLOSE_MESH')
              ENDIF
            ELSE
              CALL close_bnd(files(i)%FMT, files(i)%LU, ierr)
              CALL check_call(ierr,'BIEF_CLOSE_FILE:CLOSE_BND')
              CALL close_mesh(files(i)%FMT, files(i)%LU, ierr)
              CALL check_call(ierr,'BIEF_CLOSE_FILE:CLOSE_MESH')
            ENDIF
          ELSE
            CLOSE(files(i)%LU)
          ENDIF
!
        ENDIF
!
      ENDDO
!
!-----------------------------------------------------------------------
!
!     PARALLEL MODE: STOPS IF PEXIT
!
      IF(pexit) CALL p_exit
!
!-----------------------------------------------------------------------
!
      RETURN
      END