bief_animp.f

Go to the documentation of this file.

!                   *********************
                    SUBROUTINE bief_animp
!                   *********************

     &(format_res,varnim,n,nres,at,lt,ldir,textanim,npale)
!
!***********************************************************************
! BIEF   V7P2                                   December 2016
!***********************************************************************
!
!brief   WRITES THE WAVE HEIGHT AND WAVE PHASE TO RESULT FILE.
!       (TO BE USED TO COMPUTE THE FREE SURFACE ELEVATION AT EVERY POINT)
!
!history  J.PARISI, N.TOZER
!+        08/01/2014
!+        V6P3
!+
!
!history  N.DURAND (HRW)
!+        19/03/2014
!+        V7P0
!+   Simplified. SLF file header with variables and mesh generated outside
!+   of BIEF_DESNIM in CREATE_DATANIM_SERAFIN and WRITE_MESH_SERAFIN
!
!history  N.DURAND (HRW)
!+        Dec 2016
!+        V7P2
!+   Ported to V7P2 with use of Hermes interface to write data
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!| FORMAT_RES     |-->| FILE FORMAT
!| VARNIM         |-->| BIEF_OBJ BLOCK WITH DATA VALUES
!| N              |-->| NUMBER OF POINTS IN THE MESH
!| NRES           |-->| LOGICAL UNIT OF THE RESULTS FILE
!| AT             |-->| "TIME STAMP" (PERIOD IN THIS CASE)
!| LT             |-->| ITERATION NUMBER
!| LDIR           |-->| DIRECTION NUMBER
!| TEXTANIM       |-->| NAMES AND UNITS OF VARIABLES
!| NPALE          |-->| NUMBER OF DISCRETISED PERIODS
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      USE bief, ex_bief_animp => bief_animp
      USE interface_hermes
!
      USE declarations_special
!
      IMPLICIT NONE
!
!-----------------------------------------------------------------------
! DECLARES TYPES AND DIMENSIONS
!-----------------------------------------------------------------------
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      CHARACTER(LEN=8), INTENT(IN)          :: FORMAT_RES
      CHARACTER(LEN=32),INTENT(IN)          :: TEXTANIM(*)
      INTEGER,          INTENT(IN)          :: N, NRES
      INTEGER,          INTENT(IN)          :: LT,LDIR
      DOUBLE PRECISION, INTENT(IN)          :: AT
      TYPE(bief_obj),   INTENT(IN)          :: VARNIM
      INTEGER,          INTENT(IN)          :: NPALE
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      LOGICAL              :: FIRST_VAR
      CHARACTER(LEN=32)    :: VAR_NAME
      INTEGER              :: I,IERR
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
! IN THIS FILE, TIME STAMPS CORRESPOND TO DIFFERENT PERIOD COMPONENTS
! AND THERE ARE AS MANY (AMPLITUDE,PHASE) PAIRS AS THERE ARE DIRECTION
! COMPONENTS
!
!=======================================================================
!
      first_var = .false.
!     NEW "TIME STAMP" PRINTED TO FILE WITH EACH NEW PERIOD
!     SHOULD NOT WRITE AGAIN FOR THE NEXT DIRECTION COMPONENT
      IF (lt .LT. npale) THEN
        first_var = .true.
      ENDIF
!
!     AMPLITUDE AND PHASE FOR DIRECTION LDIR, PERIOD MOD(LT,NPALE)
!
      DO i = 1,2
        IF(ASSOCIATED(varnim%ADR(i)%P%R)) THEN
          var_name = textanim(2*(ldir-1)+i)
          CALL add_data(format_res,nres,var_name,at,mod(lt,npale),
     &                  first_var,varnim%ADR(i)%P%R,n,ierr)
          CALL check_call(ierr,'WRITE_DATASET:ADD_DATA')
          first_var = .false.
        ELSE
          WRITE(lu,*) 'WRITE_DATA: VARIABLE NO: ',i
          WRITE(lu,*) '        NOT OR NOT WELL ALLOCATED'
          WRITE(lu,*) '        OR POINTER NOT ASSOCIATED '
        ENDIF
      ENDDO
!
!=======================================================================
!
      RETURN
      END