bief_allmat.f

Go to the documentation of this file.

!                   **********************
                    SUBROUTINE bief_allmat
!                   **********************
!
     &( mat , nom , ielm1 , ielm2 , cfg , typdia , typext , mesh )
!
!***********************************************************************
! BIEF   V7P3
!***********************************************************************
!
!brief    ALLOCATES MEMORY FOR A REAL MATRIX STRUCTURE.
!
!history  J-M HERVOUET (LNH)
!+        01/03/95
!+        V5P1
!+   First version.
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        13/07/2010
!+        V6P0
!+   Translation of French comments within the FORTRAN sources into
!+   English comments
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        21/08/2010
!+        V6P0
!+   Creation of DOXYGEN tags for automated documentation and
!+   cross-referencing of the FORTRAN sources
!
!history  J-M HERVOUET (jubilado)
!+        04/11/2016
!+        V7P3
!+   Allowing several successive allocations of the same BIEF_OBJ.
!
!history  J-M HERVOUET (jubilado)
!+        08/09/2017
!+        V7P3
!+   Optional argument REFINE removed.
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!| CFG            |-->| INFORMATION ON STORAGE OF MATRIX
!|                |   | CFG(1): STORAGE   CFG(2): MATRIX-VECTOR PRODUCT
!| IELM1          |-->| TYPE OF ELEMENT PER LINE
!| IELM2          |-->| TYPE OF ELEMENT PER COLUMN
!| MAT            |<->| THE MATRIX TO BE ALLOCATED
!| MESH           |-->| MESH STRUCTURE
!| NOM            |-->| FORTRAN NAME OF MATRIX
!| TYPDIA         |-->| TYPE OF DIAGONAL ('Q', 'I' OU '0')
!| TYPEXT         |-->| TYPE OF OFF-DIAGONAL TERMS :'Q','S' OU '0'
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      USE bief, ex_bief_allmat => bief_allmat
!
      USE declarations_special
      IMPLICIT NONE
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      TYPE(bief_obj)  , INTENT(INOUT) :: MAT
      CHARACTER(LEN=6), INTENT(IN)    :: NOM
      INTEGER         , INTENT(IN)    :: IELM1,IELM2,CFG(2)
      CHARACTER(LEN=1), INTENT(IN)    :: TYPDIA,TYPEXT
      TYPE(bief_mesh) , INTENT(IN)    :: MESH
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER IELMD
!
      CHARACTER(LEN=6) :: NAME
!
!-----------------------------------------------------------------------
!  HEADER COMMON TO ALL OBJECTS
!-----------------------------------------------------------------------
!
!     KEY OF THE OBJECT - TO CHECK MEMORY CRASHES
!
      mat%KEY = 123456
!
!     TYPE OF THE OBJECT (HERE MATRIX)
!
      mat%TYPE = 3
!
!     Defines how the object was created
!
      mat%FATHER = 'XXXXXX'
!
!     NAME OF THE OBJECT
!
      mat%NAME = nom
!
!-----------------------------------------------------------------------
!  PART SPECIFIC TO MATRICES
!-----------------------------------------------------------------------
!
!     ELEMENT OF DIAGONAL (SMALLEST ELEMENT IF MATRIX IS RECTANGULAR)
      ielmd = ielm1
      IF(bief_nbpts(ielm2,mesh).LT.bief_nbpts(ielm1,mesh)) ielmd = ielm2
!
!  TYPE OF STORAGE
!
      mat%STO = cfg(1)
!
!  TYPES OF ELEMENTS FOR LINE AND COLUMN
!
      mat%ELMLIN = ielm1
      mat%ELMCOL = ielm2
!
!     ALLOCATES THE DIAGONAL (UNTIL HERE MAT%D IS ONLY A POINTER)
!
!     MAT%D WILL POINT TO A BIEF_OBJ
      IF(.NOT.ASSOCIATED(mat%D)) CALL first_all_biefobj(mat%D)
!
      name = 'D' // nom(1:5)
      IF(typdia(1:1).EQ.'Q') THEN
!       ONLY CASE WHERE THE DIAGONAL DOES EXIST
        CALL bief_allvec(1,mat%D,name,ielmd,1,2,mesh)
      ELSE
        CALL bief_allvec(1,mat%D,name,0    ,1,0,mesh)
      ENDIF
!     TYPE IS FORGOTTEN UNTIL INITIALISATION OF MATRIX
!     MAT%TYPDIA = TYPDIA(1:1)
      mat%TYPDIA = '?'
!
!     ALLOCATES OFF-DIAGONAL TERMS (AS FOR DIAGONAL)
!
      IF(.NOT.ASSOCIATED(mat%X)) CALL first_all_biefobj(mat%X)
!
      name = 'X' // nom(1:5)
!
      CALL bief_allvec(1,mat%X,name,
     &            bief_dim1_ext(ielm1,ielm2,cfg(1),typext,mesh),
     &            bief_dim2_ext(ielm1,ielm2,cfg(1),typext,mesh),0,mesh)
!
!     TYPE IS FORGOTTEN UNTIL INITIALISATION OF MATRIX
!     MAT%TYPEXT = TYPEXT(1:1)
      mat%TYPEXT = '?'
!
!     MATRIX X VECTOR PRODUCT
      mat%PRO = cfg(2)
!
!-----------------------------------------------------------------------
!
      RETURN
      END