bedload_soulsby.f

Go to the documentation of this file.

!                   **************************
                    SUBROUTINE bedload_soulsby
!                   **************************
!
     &  (ucmoy,hn, uw, npoin, dens, grav, dm, dstar, d90, qsc,
     &   qss)
!
!***********************************************************************
! SISYPHE   V6P1                                   21/07/2011
!***********************************************************************
!
!brief    SOULSBY & VAN RIJN BEDLOAD TRANSPORT FORMULATION.
!
!history  SOGREAH
!+        22/05/2001
!+        V5P2
!+
!
!history  C.VILLARET
!+        **/11/2003
!+        V5P4
!+
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        13/07/2010
!+        V6P0
!+   Translation of French comments within the FORTRAN sources into
!+   English comments
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        21/08/2010
!+        V6P0
!+   Creation of DOXYGEN tags for automated documentation and
!+   cross-referencing of the FORTRAN sources
!
!history  C.VILLARET (EDF-LNHE), P.TASSI (EDF-LNHE)
!+        19/07/2011
!+        V6P1
!+  Name of variables
!+
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!| D90            |-->| D90
!| DENS           |-->| RELATIVE DENSITY
!| DM             |-->| SEDIMENT GRAIN DIAMETER
!| DSTAR          |-->| NON-DIMENSIONAL DIAMETER
!| GRAV           |-->| ACCELERATION OF GRAVITY
!| HN             |-->| WATER DEPTH
!| NPOIN          |-->| NUMBER OF POINTS
!| QSC            |<->| BED LOAD TRANSPORT
!| QSS            |<->| SUSPENDED LOAD TRANSPORT RATE
!| UCMOY          |-->| CURRENT INTENSITY (M/S)
!| UW             |-->| ORBITAL WAVE VELOCITY
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      USE interface_sisyphe,ex_bedload_soulsby => bedload_soulsby
      USE bief
      USE declarations_special
      IMPLICIT NONE
      ! 2/ GLOBAL VARIABLES
      ! -------------------
      TYPE(bief_obj),   INTENT(IN)  :: HN, UCMOY, UW
      INTEGER,          INTENT(IN)  :: NPOIN
      DOUBLE PRECISION, INTENT(IN)  :: DENS, GRAV, DM, DSTAR, D90
      TYPE(bief_obj),   INTENT(INOUT) :: QSC, QSS
!
      ! 3/ LOCAL VARIABLES
      ! ------------------
      INTEGER                     :: I
      DOUBLE PRECISION            :: COEF, ASS, ASB, CD
      DOUBLE PRECISION            :: UCR, VTOT, TRA
      DOUBLE PRECISION, PARAMETER :: Z0=0.006d0
!
!======================================================================!
!======================================================================!
!                               PROGRAM                                !
!======================================================================!
!======================================================================!
      ! ************************* !
      ! I - SUSPENSION COEFFCIENT !
      ! ************************* !
      coef = (dens *grav*dm)**1.2d0
      ass  = 0.012d0*dm*(dstar**(-0.6d0))/coef
!
      DO i = 1, npoin
!
        ! *************************** !
        ! III - BEDLOAD COEFFICIENT   !
        ! *************************** !
        asb = 0.005d0*hn%R(i)*(dm/max(hn%R(i),dm))**1.2d0 / coef
!
        ! ********************************** !
        ! IV - ROUGHNESS COEFFICIENT CD      !
        !      SOULSBY: Z0=0.006 --> KS=18CM !
        ! ********************************** !
        cd = (0.4d0 / (log(max(hn%R(i),z0)/z0)-1.d0))**2
!
        ! ************************************************ !
        ! V - CRTITICAL CURRENT SPEED UCR                  !
        ! ************************************************ !
        IF (dm < 0.0005d0) THEN
          ucr = 0.19d0*(dm**0.1d0)*log10(4.d0*max(hn%R(i),d90)/d90)
        ELSE
          ucr = 8.50d0*(dm**0.6d0)*log10(4.d0*max(hn%R(i),d90)/d90)
        ENDIF
!
        ! ************************************************* !
        ! VI - SPEED INDUCED BY THE CURRENT AND WAVES       !
        ! ************************************************* !
        vtot = sqrt(ucmoy%R(i)**2+(0.018d0/cd)*uw%R(i)**2)
!
        ! *********************************************** !
        ! VII - SUSPENDED AND BEDLOAD TRANSPORT           !
        ! *********************************************** !
        IF (vtot > ucr) THEN
          tra     = ucmoy%R(i)  * (vtot - ucr )**2.4d0
          qss%R(i)= ass * tra
          qsc%R(i)= asb * tra
        ELSE
          qss%R(i) = 0.d0
          qsc%R(i) = 0.d0
        ENDIF
      ENDDO
!======================================================================!
!======================================================================!
      RETURN
      END SUBROUTINE bedload_soulsby