bedload_einst.f

Go to the documentation of this file.

!                   ************************
                    SUBROUTINE bedload_einst
!                   ************************
!
     &(tetap, npoin, dens, grav, dm, dstar, qsc)
!
!***********************************************************************
! SISYPHE   V6P1                                   21/07/2011
!***********************************************************************
!
!brief    EINSTEIN-BROWN BEDLOAD TRANSPORT FORMULATION.
!
!history  E. PELTIER; C. LENORMANT; J.-M. HERVOUET
!+        11/09/1995
!+        V5P1
!+
!
!history  C.VILLARET
!+        **/10/2003
!+        V5P4
!+
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        13/07/2010
!+        V6P0
!+   Translation of French comments within the FORTRAN sources into
!+   English comments
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        21/08/2010
!+        V6P0
!+   Creation of DOXYGEN tags for automated documentation and
!+   cross-referencing of the FORTRAN sources
!
!history  C.VILLARET (EDF-LNHE), P.TASSI (EDF-LNHE)
!+        19/07/2011
!+        V6P1
!+  Name of variables
!+
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!| DENS           |-->| RELATIVE SENSITY OF SEDIMENT
!| DM             |-->| SEDIMENT GRAIN DIAMETER
!| DSTAR          |-->| NON-DIMENSIONAL DIAMETER
!| GRAV           |-->| ACCELERATION OF GRAVITY
!| NPOIN          |-->| NUMBER OF POINTS
!| QSC            |<->| BED LOAD TRANSPORT
!| TETAP          |-->| ADIMENSIONAL SKIN FRICTION
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      USE interface_sisyphe, ex_bedload_einst => bedload_einst
      USE bief
      USE declarations_special
      IMPLICIT NONE
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      TYPE(bief_obj),   INTENT(IN)    :: TETAP
      INTEGER,          INTENT(IN)    :: NPOIN
      DOUBLE PRECISION, INTENT(IN)    :: DENS, GRAV, DM, DSTAR
      TYPE(bief_obj),   INTENT(INOUT)   :: QSC
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER          :: I
      DOUBLE PRECISION :: CEINST
!
!======================================================================!
!                               PROGRAM                                !
!======================================================================!
!
!     BEDLOAD TRANSPORT
!
      ceinst = 36.d0/(dstar**3)
      ceinst = sqrt(2.d0/3.d0+ceinst) -  sqrt(ceinst)
      ceinst = ceinst * sqrt(dens*grav*(dm**3))
      DO i = 1, npoin
        IF(tetap%R(i) < 2.5d-3) THEN
          qsc%R(i) = 0.d0
        ELSE IF (tetap%R(i) < 0.2d0) THEN
          qsc%R(i) = 2.15d0* ceinst * exp(-0.391d0/tetap%R(i))
        ELSE
          qsc%R(i) = 40.d0 * ceinst * (tetap%R(i)**3.d0)
        ENDIF
      ENDDO
!
!=======================================================================
!
      RETURN
      END