assve1.f

Go to the documentation of this file.

!                   *****************
                    SUBROUTINE assve1
!                   *****************
!
     &(x, ikle,w, nelem,nelmax,lv,msk,maskel)
!
!***********************************************************************
! BIEF   V6P1                                   21/08/2010
!***********************************************************************
!
!brief    ASSEMBLY LOOP FOR A VECTOR.
!
!history  J-M HERVOUET (LNH)    ; F  LEPEINTRE (LNH)
!+        18/08/94
!+        V5P1
!+
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        13/07/2010
!+        V6P0
!+   Translation of French comments within the FORTRAN sources into
!+   English comments
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        21/08/2010
!+        V6P0
!+   Creation of DOXYGEN tags for automated documentation and
!+   cross-referencing of the FORTRAN sources
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!| IKLE           |-->| CONNECTIVITY TABLE
!| LV             |-->| VECTOR LENGTH OF THE COMPUTER
!| MASKEL         |-->| MASKING OF ELEMENTS
!|                |   | =1. : NORMAL   =0. : MASKED ELEMENT
!| MSK            |-->| IF YES, THERE IS MASKED ELEMENTS.
!| NELEM          |-->| NUMBER OF ELEMENTS IN THE MESH
!| NELMAX         |-->| FIRST DIMENSION OF IKLE AND W.
!| W              |-->| WORK ARRAY WITH A NON ASSEMBLED FORM OF THE
!|                |   | RESULT
!| X              |<->| ASSEMBLED VECTOR
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      USE declarations_special
      IMPLICIT NONE
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      DOUBLE PRECISION, INTENT(INOUT) :: X(*)
      INTEGER         , INTENT(IN)    :: NELEM,NELMAX,LV
      INTEGER         , INTENT(IN)    :: IKLE(nelmax)
      DOUBLE PRECISION, INTENT(IN)    :: W(nelmax),MASKEL(*)
      LOGICAL         , INTENT(IN)    :: MSK
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER IELEM,IB
!
      INTRINSIC min
!
!-----------------------------------------------------------------------
! LOOP IN SCALAR MODE (LV=1) OR WITH FORCED VECTORISATION
!-----------------------------------------------------------------------
!
!  WITH MASKING
!
      IF(msk) THEN
!
      IF(lv.EQ.1) THEN
!
!  SCALAR MODE
!
      DO ielem = 1 , nelem
        x(ikle(ielem)) = x(ikle(ielem)) + w(ielem) * maskel(ielem)
      ENDDO ! IELEM
!
      ELSE
!
!  VECTOR MODE
!
      DO ib = 1,(nelem+lv-1)/lv
!VOCL LOOP,NOVREC
!DIR$ IVDEP
      DO ielem = 1+(ib-1)*lv , min(nelem,ib*lv)
        x(ikle(ielem)) = x(ikle(ielem)) + w(ielem) * maskel(ielem)
      ENDDO ! IELEM
      ENDDO ! IB
!
      ENDIF
!
!-----------------------------------------------------------------------
!
!  WITHOUT MASKING
!
      ELSE
!
      IF(lv.EQ.1) THEN
!
!  SCALAR MODE
!
      DO ielem = 1 , nelem
        x(ikle(ielem)) = x(ikle(ielem)) + w(ielem)
      ENDDO ! IELEM
!
      ELSE
!
!  VECTOR MODE
!
      DO ib = 1,(nelem+lv-1)/lv
!VOCL LOOP,NOVREC
!DIR$ IVDEP
      DO ielem = 1+(ib-1)*lv , min(nelem,ib*lv)
        x(ikle(ielem)) = x(ikle(ielem)) + w(ielem)
      ENDDO ! IELEM
      ENDDO ! IB
!
      ENDIF
!
      ENDIF
!
!-----------------------------------------------------------------------
!
      RETURN
      END