asseg_3d.f

Go to the documentation of this file.

!                   *******************
                    SUBROUTINE asseg_3d
!                   *******************
!
     &(flow,f,npoin3,nplan,nseg2d,gloseg,sizglo,iniflo)
!
!***********************************************************************
! BIEF   V6P1                                   21/08/2010
!***********************************************************************
!
!brief    ASSEMBLES HORIZONTAL EDGE BY EDGE FLUXES ON POINTS.
!
!history  J-M HERVOUET (LNHE)
!+        18/05/09
!+        V6P0
!+
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        13/07/2010
!+        V6P0
!+   Translation of French comments within the FORTRAN sources into
!+   English comments
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        21/08/2010
!+        V6P0
!+   Creation of DOXYGEN tags for automated documentation and
!+   cross-referencing of the FORTRAN sources
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!| F              |<--| F WHERE THE FLUXES ARE ASSEMBLED
!| FLOW           |-->| FLUXES (SIZE OF FLOW MAY NOT EXCEED
!|                |   | NSEG2D*NPLAN, THOUGH THE TOTAL NUMBER OF
!|                |   | SEGMENTS IS LARGER)
!| GLOSEG         |-->| GLOBAL NUMBER OF THE 2 POINTS OF A SEGMENT
!| INIFLO         |-->| IF(YES) F WILL BE INITIALISED AT 0.
!| NPLAN          |-->| NUMBER OF PLANES
!| NPOIN3         |-->| NUMBER OF POINTS
!| NSEG2D         |-->| NUMBER OF SEGMENTS IN 2D
!| SIZGLO         |-->| FIRST DIMENSION OF GLOSEG
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      USE bief
!
      USE declarations_special
      IMPLICIT NONE
!
!+++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
!
      INTEGER, INTENT(IN)             :: NSEG2D,NPOIN3,SIZGLO,NPLAN
      INTEGER, INTENT(IN)             :: GLOSEG(sizglo,2)
      DOUBLE PRECISION, INTENT(IN)    :: FLOW(*)
!                                        HERE * = NESG2D*NPLAN
      DOUBLE PRECISION, INTENT(INOUT) :: F(npoin3)
      LOGICAL, INTENT(IN)             :: INIFLO
!
!+++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
!
      INTEGER ISEG,I
!
!-----------------------------------------------------------------------
!
!     INITIALISES THE FLOW TO 0.D0
!
      IF(iniflo) THEN
        DO i = 1,npoin3
          f(i) = 0.d0
        ENDDO
      ENDIF
!
!-----------------------------------------------------------------------
!
!     ASSEMBLES THE FLUXES OF HORIZONTAL SEGMENTS
!
      DO iseg = 1,nseg2d*nplan
        f(gloseg(iseg,1))=f(gloseg(iseg,1))+flow(iseg)
        f(gloseg(iseg,2))=f(gloseg(iseg,2))-flow(iseg)
      ENDDO
!
!-----------------------------------------------------------------------
!
      RETURN
      END