asmve1.f

Go to the documentation of this file.

!                   *****************
                    SUBROUTINE asmve1
!                   *****************
!
     &(x, ikle,w, npoin,nelem,nelmax,lv)
!
!***********************************************************************
! BIEF   V6P1                                   21/08/2010
!***********************************************************************
!
!brief    MULTIPLICATIVE ASSEMBLY LOOP FOR A VECTOR.
!+
!+            THIS FORM OF ASSEMBLY IS USED WITH PRECONDITIONINGS
!+                OF THE TYPE ELEMENTARY 'CROUT'.
!
!history  J-M HERVOUET (LNH)    ; F  LEPEINTRE (LNH)
!+        17/08/94
!+        V5P1
!+
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        13/07/2010
!+        V6P0
!+   Translation of French comments within the FORTRAN sources into
!+   English comments
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        21/08/2010
!+        V6P0
!+   Creation of DOXYGEN tags for automated documentation and
!+   cross-referencing of the FORTRAN sources
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!| IKLE           |-->| CONNECTIVITY TABLE
!| LV             |-->| VECTOR LENGTH OF THE COMPUTER
!| NELEM          |-->| NUMBER OF ELEMENTS IN THE MESH
!| NELMAX         |-->| FIRST DIMENSION OF IKLE AND W.
!| NPOIN          |-->| NUMBER OF POINTS IN X
!| W              |-->| WORK ARRAY WITH A NON ASSEMBLED FORM OF THE
!|                |   | RESULT
!| X              |<->| ASSEMBLED VECTOR
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      USE declarations_special
      IMPLICIT NONE
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER         , INTENT(IN)    :: NELEM,NELMAX,NPOIN,LV
      DOUBLE PRECISION, INTENT(INOUT) :: X(npoin)
      INTEGER         , INTENT(IN)    :: IKLE(nelmax)
      DOUBLE PRECISION, INTENT(IN)    :: W(nelmax)
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER IELEM,IB
!
      INTRINSIC min
!
!-----------------------------------------------------------------------
! LOOP IN SCALAR MODE (LV=1) OR WITH FORCED VECTORISATION
!-----------------------------------------------------------------------
!
      IF(lv.EQ.1) THEN
!
!  SCALAR MODE
!
      DO ielem = 1 , nelem
        x(ikle(ielem)) = x(ikle(ielem)) * w(ielem)
      ENDDO ! IELEM
!
      ELSE
!
!  VECTOR MODE
!
      DO ib = 1,(nelem+lv-1)/lv
!VOCL LOOP,NOVREC
!DIR$ IVDEP
      DO ielem = 1+(ib-1)*lv , min(nelem,ib*lv)
        x(ikle(ielem)) = x(ikle(ielem)) * w(ielem)
      ENDDO ! IELEM
      ENDDO ! IB
!
      ENDIF
!
!-----------------------------------------------------------------------
!
      RETURN
      END