as3_3131_s.f

Go to the documentation of this file.

!                   *********************
                    SUBROUTINE as3_3131_s
!                   *********************
!
     &(xm,nseg,xmt,dim1xmt,dim2xmt,stoxmt,nelmax,nelem,
     & eltseg1,eltseg2,eltseg3,eltseg4,eltseg5,eltseg6)
!
!***********************************************************************
! BIEF   V6P2                                   21/08/2010
!***********************************************************************
!
!brief    ASSEMBLES MATRICES EXTRA-DIAGONAL TERMS
!+                IN THE CASE OF EDGE-BASED STORAGE.
!+
!+            CASE OF TETRAHEDRON ELEMENT AND SYMMETRICAL MATRIX.
!
!history  J-M HERVOUET (LNHE)
!+        25/08/2011
!+        V6P2
!+
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!| DIM1XMT        |-->| FIRST DIMENSION OF XMT
!| DIM2XMT        |-->| SECOND DIMENSION OF XMT
!| ELTSEG1        |-->| FIRST SEGMENT OF A TRIANGLE
!| ELTSEG2        |-->| SECOND SEGMENT OF A TRIANGLE
!| ELTSEG3        |-->| THIRD SEGMENT OF A TRIANGLE
!| ELTSEG4        |-->| FOURTH SEGMENT OF A QUADRATIC TRIANGLE
!| ELTSEG5        |-->| FIFTH SEGMENT OF A QUADRATIC TRIANGLE
!| ELTSEG6        |-->| SIXTH SEGMENT OF A QUADRATIC TRIANGLE
!| NELEM          |-->| NUMBER OF ELEMENTS IN THE MESH
!| NELMAX         |-->| FIRST DIMENSION OF IKLE AND W.
!| NSEG           |-->| NUMBER OF SEGMENTS
!| STOXMT         |-->| STORAGE MODE OF XMT
!| XM             |<--| ASSEMBLED OFF-DIAGONAL TERMS XA12,23,31
!| XMT            |-->| ELEMENT BY ELEMENT STORAGE OF MATRIX
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      USE declarations_special
      IMPLICIT NONE
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER         , INTENT(IN)    :: NELMAX,NELEM,NSEG
      INTEGER         , INTENT(IN)    :: DIM1XMT,DIM2XMT,STOXMT
      INTEGER         , INTENT(IN)    :: ELTSEG1(nelmax),ELTSEG2(nelmax)
      INTEGER         , INTENT(IN)    :: ELTSEG3(nelmax),ELTSEG4(nelmax)
      INTEGER         , INTENT(IN)    :: ELTSEG5(nelmax),ELTSEG6(nelmax)
      DOUBLE PRECISION, INTENT(INOUT) :: XMT(dim1xmt,dim2xmt)
      DOUBLE PRECISION, INTENT(INOUT) :: XM(nseg)
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER ISEG,IELEM
!
!-----------------------------------------------------------------------
!
!  INITIALISES
!
      DO iseg = 1 , nseg
        xm(iseg) = 0.d0
      ENDDO
!
!-----------------------------------------------------------------------
!
      IF(stoxmt.EQ.1) THEN
!
!     ASSEMBLES
!
      DO ielem = 1,nelem
!       TERM 12
        xm(eltseg1(ielem)) = xm(eltseg1(ielem)) + xmt(ielem,1)
!       TERM 23
        xm(eltseg2(ielem)) = xm(eltseg2(ielem)) + xmt(ielem,4)
!       TERM 31
        xm(eltseg3(ielem)) = xm(eltseg3(ielem)) + xmt(ielem,2)
!       TERM 14
        xm(eltseg4(ielem)) = xm(eltseg4(ielem)) + xmt(ielem,3)
!       TERM 24
        xm(eltseg5(ielem)) = xm(eltseg5(ielem)) + xmt(ielem,5)
!       TERM 34
        xm(eltseg6(ielem)) = xm(eltseg6(ielem)) + xmt(ielem,6)
      ENDDO
!
!-----------------------------------------------------------------------
!
      ELSEIF(stoxmt.EQ.2) THEN
!
!     ASSEMBLES
!
      DO ielem = 1,nelem
!       TERM 12
        xm(eltseg1(ielem)) = xm(eltseg1(ielem)) + xmt(1,ielem)
!       TERM 23
        xm(eltseg2(ielem)) = xm(eltseg2(ielem)) + xmt(4,ielem)
!       TERM 31
        xm(eltseg3(ielem)) = xm(eltseg3(ielem)) + xmt(2,ielem)
!       TERM 14
        xm(eltseg4(ielem)) = xm(eltseg4(ielem)) + xmt(3,ielem)
!       TERM 24
        xm(eltseg5(ielem)) = xm(eltseg5(ielem)) + xmt(5,ielem)
!       TERM 34
        xm(eltseg6(ielem)) = xm(eltseg6(ielem)) + xmt(6,ielem)
      ENDDO
!
!-----------------------------------------------------------------------
!
      ELSE
        WRITE(lu,*) 'AS3_3131_S: UNKNOWN STORAGE OF XMT : ',stoxmt
        CALL plante(1)
        stop
      ENDIF
!
!-----------------------------------------------------------------------
!
      RETURN
      END