as3_1313_s.f

Go to the documentation of this file.

!                   *********************
                    SUBROUTINE as3_1313_s
!                   *********************
!
     &(xm,nseg1,xmt,dim1xmt,dim2xmt,stoxmt,nelmax,nelem,eltseg)
!
!***********************************************************************
! BIEF   V6P1                                   21/08/2010
!***********************************************************************
!
!brief    ASSEMBLES MATRICES EXTRA-DIAGONAL TERMS
!+                IN THE CASE OF EDGE-BASED STORAGE.
!+
!+            CASE OF QUADRATIC TRIANGLE AND SYMMETRICAL MATRIX.
!code
!+            LOCAL NUMBERING OF SEGMENTS CHOSEN HERE IN A TRIANGLE
!+
!+            01 --> 1 - 2
!+            02 --> 2 - 3
!+            03 --> 3 - 1
!+            04 --> 1 - 4
!+            05 --> 2 - 5
!+            06 --> 3 - 6
!+            07 --> 2 - 4
!+            08 --> 3 - 5
!+            09 --> 1 - 6
!+            10 --> 1 - 5
!+            11 --> 2 - 6
!+            12 --> 3 - 4
!+            13 --> 4 - 5
!+            14 --> 5 - 6
!+            15 --> 6 - 4
!+
!+            LOCAL NUMBERING OF ELEMENT BY ELEMENT EXTRA-DIAGONAL TERMS
!+
!+            01 : POINTS 1-2
!+            02 : POINTS 1-3
!+            03 : POINTS 1-4
!+            04 : POINTS 1-5
!+            05 : POINTS 1-6
!+            06 : POINTS 2-3
!+            07 : POINTS 2-4
!+            08 : POINTS 2-5
!+            09 : POINTS 2-6
!+            10 : POINTS 3-4
!+            11 : POINTS 3-5
!+            12 : POINTS 3-6
!+            13 : POINTS 4-5
!+            14 : POINTS 4-6
!+            15 : POINTS 5-6
!
!history  J-M HERVOUET (LNHE)
!+        05/02/2010
!+        V6P0
!+
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        13/07/2010
!+        V6P0
!+   Translation of French comments within the FORTRAN sources into
!+   English comments
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        21/08/2010
!+        V6P0
!+   Creation of DOXYGEN tags for automated documentation and
!+   cross-referencing of the FORTRAN sources
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!| DIM1XMT        |-->| FIRST DIMENSION OF XMT
!| DIM2XMT        |-->| SECOND DIMENSION OF XMT
!| ELTSEG         |-->| SEGMENTS OF A TRIANGLE
!| NELEM          |-->| NUMBER OF ELEMENTS IN THE MESH
!| NELMAX         |-->| FIRST DIMENSION OF IKLE AND W.
!| NSEG1          |-->| NUMBER OF SEGMENTS
!| ORISEG         |-->| ORIENTATION OF SEGMENTS
!| STOXMT         |-->| STORAGE OF XMT 1: (NELMAX,*)
!|                |   |                2: (*,NELMAX)
!| XM             |<--| ASSEMBLED OFF-DIAGONAL TERMS XA12,23,31
!| XMT            |-->| ELEMENT BY ELEMENT STORAGE OF MATRIX
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      USE declarations_special
      IMPLICIT NONE
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER         , INTENT(IN)    :: NELMAX,NELEM,NSEG1
      INTEGER         , INTENT(IN)    :: DIM1XMT,DIM2XMT,STOXMT
      INTEGER         , INTENT(IN)    :: ELTSEG(nelmax,15)
      DOUBLE PRECISION, INTENT(IN)    :: XMT(dim1xmt,dim2xmt)
      DOUBLE PRECISION, INTENT(INOUT) :: XM(nseg1)
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER ISEG,IELEM
!
!-----------------------------------------------------------------------
!
!  INITIALISES
!
      DO iseg = 1 , nseg1
        xm(iseg) = 0.d0
      ENDDO
!
!-----------------------------------------------------------------------
!
!  ASSEMBLES
!
!-----------------------------------------------------------------------
!
      IF(stoxmt.EQ.1) THEN
!
      DO ielem = 1,nelem
!
          xm(eltseg(ielem,01))=xm(eltseg(ielem,01))+xmt(ielem,01)
          xm(eltseg(ielem,02))=xm(eltseg(ielem,02))+xmt(ielem,06)
          xm(eltseg(ielem,03))=xm(eltseg(ielem,03))+xmt(ielem,02)
          xm(eltseg(ielem,04))=xm(eltseg(ielem,04))+xmt(ielem,03)
          xm(eltseg(ielem,05))=xm(eltseg(ielem,05))+xmt(ielem,08)
          xm(eltseg(ielem,06))=xm(eltseg(ielem,06))+xmt(ielem,12)
          xm(eltseg(ielem,07))=xm(eltseg(ielem,07))+xmt(ielem,07)
          xm(eltseg(ielem,08))=xm(eltseg(ielem,08))+xmt(ielem,11)
          xm(eltseg(ielem,09))=xm(eltseg(ielem,09))+xmt(ielem,05)
          xm(eltseg(ielem,10))=xm(eltseg(ielem,10))+xmt(ielem,04)
          xm(eltseg(ielem,11))=xm(eltseg(ielem,11))+xmt(ielem,09)
          xm(eltseg(ielem,12))=xm(eltseg(ielem,12))+xmt(ielem,10)
          xm(eltseg(ielem,13))=xm(eltseg(ielem,13))+xmt(ielem,13)
          xm(eltseg(ielem,14))=xm(eltseg(ielem,14))+xmt(ielem,15)
          xm(eltseg(ielem,15))=xm(eltseg(ielem,15))+xmt(ielem,14)
!
      ENDDO
!
      ELSEIF(stoxmt.EQ.2) THEN
!
      DO ielem = 1,nelem
!
          xm(eltseg(ielem,01))=xm(eltseg(ielem,01))+xmt(01,ielem)
          xm(eltseg(ielem,02))=xm(eltseg(ielem,02))+xmt(06,ielem)
          xm(eltseg(ielem,03))=xm(eltseg(ielem,03))+xmt(02,ielem)
          xm(eltseg(ielem,04))=xm(eltseg(ielem,04))+xmt(03,ielem)
          xm(eltseg(ielem,05))=xm(eltseg(ielem,05))+xmt(08,ielem)
          xm(eltseg(ielem,06))=xm(eltseg(ielem,06))+xmt(12,ielem)
          xm(eltseg(ielem,07))=xm(eltseg(ielem,07))+xmt(07,ielem)
          xm(eltseg(ielem,08))=xm(eltseg(ielem,08))+xmt(11,ielem)
          xm(eltseg(ielem,09))=xm(eltseg(ielem,09))+xmt(05,ielem)
          xm(eltseg(ielem,10))=xm(eltseg(ielem,10))+xmt(04,ielem)
          xm(eltseg(ielem,11))=xm(eltseg(ielem,11))+xmt(09,ielem)
          xm(eltseg(ielem,12))=xm(eltseg(ielem,12))+xmt(10,ielem)
          xm(eltseg(ielem,13))=xm(eltseg(ielem,13))+xmt(13,ielem)
          xm(eltseg(ielem,14))=xm(eltseg(ielem,14))+xmt(15,ielem)
          xm(eltseg(ielem,15))=xm(eltseg(ielem,15))+xmt(14,ielem)
!
      ENDDO
!
      ELSE
        WRITE(lu,*) 'AS3_1313_S: UNKNOWN STORAGE OF XMT : ',stoxmt
        CALL plante(1)
        stop
      ENDIF
!
!-----------------------------------------------------------------------
!
      RETURN
      END