as3_1112.f

Go to the documentation of this file.

!                   *******************
                    SUBROUTINE as3_1112
!                   *******************
!
     &(xm,nseg11,nseg12,xmt,nelmax,nelem,eltseg1,eltseg2,eltseg3,
     &                                   eltseg4,eltseg5,eltseg6,
     &                                   oriseg1,oriseg2,oriseg3)
!
!***********************************************************************
! BIEF   V6P1                                   21/08/2010
!***********************************************************************
!
!brief    ASSEMBLES MATRICES EXTRA-DIAGONAL TERMS
!+                IN THE CASE OF EDGE-BASED STORAGE.
!+
!+            CASE OF LINEAR-QUASIBUBBLE ELEMENT.
!code
!+            THE EXTRA-DIAGONAL TERMS OF THIS RECTANGULAR MATRIX ARE :
!+
!+            ... 1-2 1-3 1-4
!+            2-1 ... 2-3 2-4
!+            3-1 3-2 ... 3-4
!+
!+            AND ARE STORED LIKE A SQUARE LINEAR MATRIX + 3 TERMS
!+            WHICH GIVES 2*NSEG11 + (NSEG12-NSEG11) TERMS
!+            OR NSEG11 + NSEG12, HENCE THE DIMENSION OF XM
!
!history  J-M HERVOUET (LNH)
!+        29/12/05
!+        V5P6
!+
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        13/07/2010
!+        V6P0
!+   Translation of French comments within the FORTRAN sources into
!+   English comments
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        21/08/2010
!+        V6P0
!+   Creation of DOXYGEN tags for automated documentation and
!+   cross-referencing of the FORTRAN sources
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!| ELTSEG1        |-->| FIRST SEGMENT OF A TRIANGLE
!| ELTSEG2        |-->| SECOND SEGMENT OF A TRIANGLE
!| ELTSEG3        |-->| THIRD SEGMENT OF A TRIANGLE
!| ELTSEG4        |-->| FOURTH SEGMENT OF A QUASI-BUBBLE TRIANGLE
!| ELTSEG5        |-->| FIFTH SEGMENT OF A QUASI-BUBBLE TRIANGLE
!| ELTSEG6        |-->| SIXTH SEGMENT OF A QUASI-BUBBLE TRIANGLE
!| NELEM          |-->| NUMBER OF ELEMENTS IN THE MESH
!| NELMAX         |-->| FIRST DIMENSION OF IKLE AND W.
!| NSEG11         |-->| NUMBER OF SEGMENTS (HERE JOINING LINEAR POINTS)
!| NSEG12         |-->| NUMBER OF SEGMENTS (HERE QUASI-BUBBLE)
!| ORISEG1        |-->| ORIENTATION OF SEGMENT 1 OF TRIANGLE
!| ORISEG2        |-->| ORIENTATION OF SEGMENT 2 OF TRIANGLE
!| ORISEG3        |-->| ORIENTATION OF SEGMENT 3 OF TRIANGLE
!| XM             |<--| ASSEMBLED OFF-DIAGONAL TERMS XA12,23,31
!| XMT            |-->| ELEMENT BY ELEMENT STORAGE OF MATRIX
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      USE declarations_special
      IMPLICIT NONE
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER         , INTENT(IN)    :: NELMAX,NELEM,NSEG11,NSEG12
      INTEGER         , INTENT(IN)    :: ELTSEG1(nelmax)
      INTEGER         , INTENT(IN)    :: ELTSEG2(nelmax)
      INTEGER         , INTENT(IN)    :: ELTSEG3(nelmax)
      INTEGER         , INTENT(IN)    :: ELTSEG4(nelmax)
      INTEGER         , INTENT(IN)    :: ELTSEG5(nelmax)
      INTEGER         , INTENT(IN)    :: ELTSEG6(nelmax)
      INTEGER         , INTENT(IN)    :: ORISEG1(nelmax)
      INTEGER         , INTENT(IN)    :: ORISEG2(nelmax)
      INTEGER         , INTENT(IN)    :: ORISEG3(nelmax)
      DOUBLE PRECISION, INTENT(IN)    :: XMT(nelmax,*)
      DOUBLE PRECISION, INTENT(INOUT) :: XM(nseg11+nseg12)
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER ISEG,IELEM
!
!-----------------------------------------------------------------------
!
!  INITIALISES
!
      DO iseg = 1 , 2*nseg11
        xm(iseg) = 0.d0
      ENDDO
!
!  ASSEMBLES THE LINEAR PART (BETWEEN 1 AND 2*NSEG11)
!
!  THE SHIFT NSEG11*(...) PLACES THE TERM IN THE HIGHER OR LOWER
!  OFF-DIAGONAL TERMS, DEPENDING ON THE ORIENTATION OF THE SEGMENT
!
      DO ielem = 1,nelem
!         TERM 12
          xm(eltseg1(ielem)+nseg11*(oriseg1(ielem)-1))
     &  = xm(eltseg1(ielem)+nseg11*(oriseg1(ielem)-1)) + xmt(ielem,01)
!         TERM 23
          xm(eltseg2(ielem)+nseg11*(oriseg2(ielem)-1))
     &  = xm(eltseg2(ielem)+nseg11*(oriseg2(ielem)-1)) + xmt(ielem,05)
!         TERM 31
          xm(eltseg3(ielem)+nseg11*(oriseg3(ielem)-1))
     &  = xm(eltseg3(ielem)+nseg11*(oriseg3(ielem)-1)) + xmt(ielem,07)
!         TERM 21
          xm(eltseg1(ielem)+nseg11*(2-oriseg1(ielem)))
     &  = xm(eltseg1(ielem)+nseg11*(2-oriseg1(ielem))) + xmt(ielem,04)
!         TERM 32
          xm(eltseg2(ielem)+nseg11*(2-oriseg2(ielem)))
     &  = xm(eltseg2(ielem)+nseg11*(2-oriseg2(ielem))) + xmt(ielem,08)
!         TERM 13
          xm(eltseg3(ielem)+nseg11*(2-oriseg3(ielem)))
     &  = xm(eltseg3(ielem)+nseg11*(2-oriseg3(ielem))) + xmt(ielem,02)
      ENDDO
!
!  ASSEMBLES THE QUASI-BUBBLE PART
!  BETWEEN XM(2*NSEG11+1) AND XM(NSEG11+NSEG12)
!  SEE IN STOSEG HOW ELTSEG4,5,6 ARE BUILT
!
      DO ielem = 1,nelem
!       TERM 14
        xm(eltseg4(ielem)+nseg11) = xmt(ielem,03)
!       TERM 24
        xm(eltseg5(ielem)+nseg11) = xmt(ielem,06)
!       TERM 34
        xm(eltseg6(ielem)+nseg11) = xmt(ielem,09)
      ENDDO
!
!-----------------------------------------------------------------------
!
      RETURN
      END