as3_1111_q.f

Go to the documentation of this file.

!                   *********************
                    SUBROUTINE as3_1111_q
!                   *********************
!
     &(xm,nseg1,xmt,dim1xmt,dim2xmt,nelmax,nelem,stoxmt,
     & eltseg1,eltseg2,eltseg3,oriseg1,oriseg2,oriseg3)
!
!***********************************************************************
! BIEF   V6P1                                   21/08/2010
!***********************************************************************
!
!brief    ASSEMBLES MATRICES EXTRA-DIAGONAL TERMS
!+                IN THE CASE OF EDGE-BASED STORAGE.
!+
!+            CASE OF LINEAR-LINEAR ELEMENT
!+                AND NON SYMMETRICAL MATRIX.
!
!history  J-M HERVOUET (LNH)
!+        30/06/99
!+        V5P1
!+
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        13/07/2010
!+        V6P0
!+   Translation of French comments within the FORTRAN sources into
!+   English comments
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        21/08/2010
!+        V6P0
!+   Creation of DOXYGEN tags for automated documentation and
!+   cross-referencing of the FORTRAN sources
!
!history  S. PAVAN (LNHE)
!+        30/06/99
!+        V6P3
!+   Two storages of extra-diagonal terms treated.
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!| ELTSEG1        |-->| FIRST SEGMENT OF A TRIANGLE
!| ELTSEG2        |-->| SECOND SEGMENT OF A TRIANGLE
!| ELTSEG3        |-->| THIRD SEGMENT OF A TRIANGLE
!| NELEM          |-->| NUMBER OF ELEMENTS IN THE MESH
!| NELMAX         |-->| FIRST DIMENSION OF IKLE AND W.
!| NSEG1          |-->| NUMBER OF SEGMENTS (HERE JOINING LINEAR POINTS)
!| ORISEG1        |-->| ORIENTATION OF SEGMENT 1 OF TRIANGLE
!| ORISEG2        |-->| ORIENTATION OF SEGMENT 2 OF TRIANGLE
!| ORISEG3        |-->| ORIENTATION OF SEGMENT 3 OF TRIANGLE
!| XM             |<--| ASSEMBLED OFF-DIAGONAL TERMS XA12,23,31
!| XMT            |-->| ELEMENT BY ELEMENT STORAGE OF MATRIX
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      USE declarations_special
      IMPLICIT NONE
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER         , INTENT(IN)    :: NELMAX,NELEM,NSEG1
      INTEGER         , INTENT(IN)    :: DIM1XMT,DIM2XMT,STOXMT
      INTEGER         , INTENT(IN)    :: ELTSEG1(nelmax)
      INTEGER         , INTENT(IN)    :: ELTSEG2(nelmax)
      INTEGER         , INTENT(IN)    :: ELTSEG3(nelmax)
      INTEGER         , INTENT(IN)    :: ORISEG1(nelmax)
      INTEGER         , INTENT(IN)    :: ORISEG2(nelmax)
      INTEGER         , INTENT(IN)    :: ORISEG3(nelmax)
      DOUBLE PRECISION, INTENT(INOUT) :: XMT(dim1xmt,dim2xmt)
      DOUBLE PRECISION, INTENT(INOUT) :: XM(nseg1,2)
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER ISEG,IELEM
!
!-----------------------------------------------------------------------
!
!  INITIALISES
!
      DO iseg = 1 , nseg1
        xm(iseg,1) = 0.d0
        xm(iseg,2) = 0.d0
      ENDDO
!
!  ASSEMBLES
!
      IF(stoxmt.EQ.1) THEN
!
      DO ielem = 1,nelem
!         TERM 12
          xm(eltseg1(ielem),  oriseg1(ielem))
     &  = xm(eltseg1(ielem),  oriseg1(ielem)) + xmt(ielem,1)
!         TERM 23
          xm(eltseg2(ielem),  oriseg2(ielem))
     &  = xm(eltseg2(ielem),  oriseg2(ielem)) + xmt(ielem,3)
!         TERM 31
          xm(eltseg3(ielem),  oriseg3(ielem))
     &  = xm(eltseg3(ielem),  oriseg3(ielem)) + xmt(ielem,5)
!         TERM 21
          xm(eltseg1(ielem),3-oriseg1(ielem))
     &  = xm(eltseg1(ielem),3-oriseg1(ielem)) + xmt(ielem,4)
!         TERM 32
          xm(eltseg2(ielem),3-oriseg2(ielem))
     &  = xm(eltseg2(ielem),3-oriseg2(ielem)) + xmt(ielem,6)
!         TERM 13
          xm(eltseg3(ielem),3-oriseg3(ielem))
     &  = xm(eltseg3(ielem),3-oriseg3(ielem)) + xmt(ielem,2)
      ENDDO
!
!-----------------------------------------------------------------------
!
      ELSEIF(stoxmt.EQ.2) THEN
!
!     ASSEMBLES
!
      DO ielem = 1,nelem
!         TERM 12
          xm(eltseg1(ielem),  oriseg1(ielem))
     &  = xm(eltseg1(ielem),  oriseg1(ielem)) + xmt(1,ielem)
!         TERM 23
          xm(eltseg2(ielem),  oriseg2(ielem))
     &  = xm(eltseg2(ielem),  oriseg2(ielem)) + xmt(3,ielem)
!         TERM 31
          xm(eltseg3(ielem),  oriseg3(ielem))
     &  = xm(eltseg3(ielem),  oriseg3(ielem)) + xmt(5,ielem)
!         TERM 21
          xm(eltseg1(ielem),3-oriseg1(ielem))
     &  = xm(eltseg1(ielem),3-oriseg1(ielem)) + xmt(4,ielem)
!         TERM 32
          xm(eltseg2(ielem),3-oriseg2(ielem))
     &  = xm(eltseg2(ielem),3-oriseg2(ielem)) + xmt(6,ielem)
!         TERM 13
          xm(eltseg3(ielem),3-oriseg3(ielem))
     &  = xm(eltseg3(ielem),3-oriseg3(ielem)) + xmt(2,ielem)
!
      ENDDO
!
!-----------------------------------------------------------------------
!
      ELSE
        WRITE(lu,*) 'AS3_1111_Q: UNKNOWN STORAGE OF XMT : ',stoxmt
        CALL plante(1)
        stop
      ENDIF
!
!-----------------------------------------------------------------------
!
      RETURN
      END