allspec.f

Go to the documentation of this file.

!                       ******************
                        SUBROUTINE allspec
!                       ******************
!
     &(spec,nom)
!
!***********************************************************************
! ARTEMIS   V8P0                                     Jan 2019
!***********************************************************************
!
!brief    ALLOCATES MEMORY FOR A SPECTRAL DATA STRUCTURE : SPEC.
!
!history  N.DURAND (HRW)
!+        09/03/01
!+
!+   Original
!
!history  SRIRAM VENKATACHALAM (HRW)
!+        13/08/08
!+
!+   Modified to be compatible with Artemis v5.8
!+   After executing allvec, the newer version will fill the arrays with
!+   huge numbers in order to check whether the array is initialised or
!+   not. Hence, we need to re-initialise the array with zeros.
!
!history  N.DURAND (HRW)
!+        20/06/14
!+        V7P0
!+   bief_allvec not used anymore as support is not MESH
!+   Streamlined for V7P0
!
!history  N.DURAND (HRW)
!+        Feb 2017
!+        V7P2
!+   Updated for V7P2
!
!history  N.DURAND (HRW)
!+        Jan 2019
!+        V8P0
!+   Tidied up
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!| SPEC           |<--| STRUCTURE TO BE ALLOCATED
!| NOM            |-->| NAME OF THE STRUCTURE SPECTRUM
!| OUTERMODEL     |-->| IS THE STRUCTURE FOR THE OUTER MODEL OR ARTEMIS?
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      USE bief
      USE declarations_artemis
!
      USE declarations_special
      IMPLICIT NONE
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      TYPE(spectrum)   , INTENT(INOUT)        :: SPEC
      CHARACTER(LEN=6) , INTENT(IN)           :: NOM
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER IERR
      INTEGER I,II,JJ
!
!-----------------------------------------------------------------------
!  HEADER COMMON TO ALL OBJECTS IN SPEC
!-----------------------------------------------------------------------
!
      spec%NAME  = nom
!
!     NUMBER OF OBJECTS IN SPEC
      spec%N = nspec
!
!     DIRECTION COMPONENTS IN SPEC
!     +1 TO CLOSE THE LOOP
      ALLOCATE (spec%DIR(ndir+1),stat=ierr)
      CALL check_allocate(ierr,'ALLSPEC:SPEC%DIR')
      CALL ov('X=C     ',spec%DIR,spec%DIR,spec%DIR,0.d0,ndir+1)
!
!     FREQUENCY COMPONENTS
      ALLOCATE (spec%FRE(nf),stat=ierr)
      CALL check_allocate(ierr,'ALLSPEC:SPEC%FRE')
      CALL ov('X=C     ',spec%FRE,spec%FRE,spec%FRE,0.d0,nf)
!
!_______________________________________________________________________
!
!     NODE NUMBER
      ALLOCATE (spec%NOUTER(nspec),stat=ierr)
      CALL check_allocate(ierr,'ALLSPEC:SPEC%NOUTER')
      DO i=1,nspec
        spec%NOUTER(i) = 0
      ENDDO
!     X COORDINATE
      ALLOCATE (spec%XOUTER(nspec),stat=ierr)
      CALL check_allocate(ierr,'ALLSPEC:SPEC%XOUTER')
      CALL ov
     & ('X=C     ',spec%XOUTER,spec%XOUTER,spec%XOUTER,0.d0,nspec)
!     Y COORDINATE
      ALLOCATE (spec%YOUTER(nspec),stat=ierr)
      CALL check_allocate(ierr,'ALLSPEC:SPEC%YOUTER')
      CALL ov
     & ('X=C     ',spec%YOUTER,spec%YOUTER,spec%YOUTER,0.d0,nspec)
!
!-----------------------------------------------------------------------
!     ALLOCATES THE POINTERS ARRAY ADR
!-----------------------------------------------------------------------
!
      ALLOCATE(spec%ADR(spec%N),stat=ierr)
      CALL check_allocate(ierr,'ALLSPEC:SPEC%ADR')
      WRITE(lu,*) 'SPECTRUM: ',nom,' ALLOCATED'
!
!_______________________________________________________________________
!
      DO i=1,nspec
        ALLOCATE(spec%ADR(i)%SOUTER(nf,ndir+1),stat=ierr)
        CALL check_allocate(ierr,'ALLSPEC:SPEC%ADR(I)%SOUTER')
        DO ii=1,nf
          DO jj=1,ndir+1
            spec%ADR(i)%SOUTER(ii,jj)=0.d0
          ENDDO
        ENDDO
      ENDDO
!
!_______________________________________________________________________
!
      RETURN
      END