allblo_in_block.f

Go to the documentation of this file.

!                   **************************
                    SUBROUTINE allblo_in_block
!                   **************************
!
     &( blo , n , nomgen )
!
!***********************************************************************
! BIEF   V6P1                                   21/08/2010
!***********************************************************************
!
!brief    ALLOCATES MEMORY FOR N BLOCKS, WHICH WILL BE PART
!+                OF A GIVEN BLOCK.
!
!history  J-M HERVOUET (LNH)
!+        11/07/95
!+        V5P1
!+
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        13/07/2010
!+        V6P0
!+   Translation of French comments within the FORTRAN sources into
!+   English comments
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        21/08/2010
!+        V6P0
!+   Creation of DOXYGEN tags for automated documentation and
!+   cross-referencing of the FORTRAN sources
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!| BLO            |<->| BLOCK WHERE TO ALLOCATE THE BLOCK STRUCTURES
!| N              |-->| NUMBER OF BLOCKS TO BE ADDED IN BLO
!| NOMGEN         |-->| GENERIC FORTRAN NAME OF THE BLOCKS
!|                |   | IT WILL BE COMPLETED WITH THEIR RANK
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      USE bief, ex_allblo_in_block => allblo_in_block
!
      USE declarations_special
      IMPLICIT NONE
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      TYPE(bief_obj)  , INTENT(INOUT) :: BLO
      INTEGER         , INTENT(IN)    :: N
      CHARACTER(LEN=6), INTENT(IN)    :: NOMGEN
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER IDEB,I,II
!
      CHARACTER(LEN=6) :: NOM
      CHARACTER(LEN=1), PARAMETER :: CHIFFRE(0:9) =
     &            (/'0','1','2','3','4','5','6','7','8','9'/)
!
!-----------------------------------------------------------------------
!
      ideb = 6
      DO i=5,2,-1
        IF(nomgen(i:i).EQ.' ') ideb = i
      ENDDO ! I
!
!-----------------------------------------------------------------------
!
      IF(n.LE.blo%MAXBLOCK) THEN
!
      DO i = 1 , n
!
!       NAME OF THE BLOCK
!
        nom=nomgen
        IF(i.LT.10) THEN
          ideb = min(6,ideb)
          nom(ideb:ideb) = chiffre(i)
        ELSEIF(i.LT.100) THEN
          ideb = min(5,ideb)
          nom(ideb  :ideb  ) = chiffre(i/10)
          nom(ideb+1:ideb+1) = chiffre(i-10*(i/10))
        ELSEIF(i.LT.1000) THEN
          ideb = min(4,ideb)
          nom(ideb  :ideb  ) = chiffre(i/100)
          ii=i-100*(i/100)
          nom(ideb+1:ideb+1) = chiffre(ii/10)
          nom(ideb+2:ideb+2) = chiffre(ii-10*(ii/10))
        ELSE
          WRITE(lu,*) 'TOO MANY BLOCKS IN ALLBLO_IN_BLOCK'
          CALL plante(1)
          stop
        ENDIF
!
!       ALLOCATES THE BLOCK IF NOT ALREADY DONE
!
        CALL first_all_biefobj(blo%ADR(i)%P)
        CALL allblo(blo%ADR(i)%P,nom)
        blo%N=blo%N+1
        blo%ADR(i)%P%FATHER = blo%NAME
!
      ENDDO
!
      ELSE
!
        WRITE(lu,*) 'ALLBLO_IN_BLOCK : MORE THAN '
        WRITE(lu,*) '                 ',blo%MAXBLOCK,' (',n,')'
        WRITE(lu,*) '                  BLOCKS TO BE ALLOCATED'
        WRITE(lu,*) '                  CHANGE MAXBLOCK IN ALLBLO'
        CALL plante(1)
        stop
!
      ENDIF
!
!-----------------------------------------------------------------------
!
      RETURN
      END