allblo.f

Go to the documentation of this file.

!                   *****************
                    SUBROUTINE allblo
!                   *****************
!
     &( blo , nom )
!
!***********************************************************************
! BIEF   V7P3
!***********************************************************************
!
!brief    ALLOCATES MEMORY FOR A BLOCK STRUCTURE.
!
!history  J-M HERVOUET (LNH)
!+        10/01/95
!+        V5P5
!+
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        13/07/2010
!+        V6P0
!+   Translation of French comments within the FORTRAN sources into
!+   English comments
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        21/08/2010
!+        V6P0
!+   Creation of DOXYGEN tags for automated documentation and
!+   cross-referencing of the FORTRAN sources
!
!history  J-M HERVOUET (LNHE)
!+        09/08/2011
!+        V6P25
!+   Maximum size BLO%MAXBLOCK increased from 128 to 256
!+
!history  J-M HERVOUET (jubilado)
!+        04/11/2016
!+        V7P3
!+   Allowing several successive allocations of the same BIEF_OBJ.
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!| BLO            |-->| THE BLOCK TO BE ALLOCATED
!| NOM            |-->| FORTRAN NAME OF THIS BLOCK
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      USE bief, ex_allblo => allblo
!
      USE declarations_special
      IMPLICIT NONE
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      TYPE(bief_obj)  , INTENT(INOUT) :: BLO
      CHARACTER(LEN=6), INTENT(IN)    :: NOM
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER I,ERR
!
!-----------------------------------------------------------------------
!  COMMON PART FOR ALL OBJECTS
!-----------------------------------------------------------------------
!
!     KEY OF THE OBJECT
!
      blo%KEY = 123456
!
!     TYPE OF THE OBJECT
!
      blo%TYPE = 4
!
!     Defines how the object was created
!
      blo%FATHER = 'XXXXXX'
!
!     NAME OF THE OBJECT
!
      blo%NAME = nom
!
!-----------------------------------------------------------------------
!  PART SPECIFIC TO BLOCKS
!-----------------------------------------------------------------------
!
!     NUMBER OF OBJECTS IN THE BLOCK
!
      blo%N = 0
!
!     ALLOCATES THE POINTERS ARRAY ADR
!
      blo%MAXBLOCK = 256
      err=0
      IF(.NOT.ASSOCIATED(blo%ADR)) THEN
        ALLOCATE(blo%ADR(blo%MAXBLOCK),stat=err)
        DO i=1,blo%MAXBLOCK
          NULLIFY(blo%ADR(i)%P)
        ENDDO
      ENDIF
!
!-----------------------------------------------------------------------
!
      IF(err.NE.0) THEN
        WRITE(lu,20) nom,err
20      FORMAT(1x,'ERROR DURING ALLOCATION OF BLOCK: ',a6,/,1x,
     &            'ERROR CODE: ',1i6)
        CALL plante(1)
        stop
      ENDIF
!
!-----------------------------------------------------------------------
!
      RETURN
      END