aidelu.f

Go to the documentation of this file.

!                   *****************
                    SUBROUTINE aidelu
!                   *****************
!
     &( icol , ligne, doc )
!
!***********************************************************************
! DAMOCLES   V6P0                                   21/08/2010
!***********************************************************************
!
!brief    DECODES A CHARACTER STRING FROM COLUMN ICOL+1
!+             OF A LINE  (80 CHARACTERS MAXIMUM PER LINE).
!+             THIS STRING CAN RUN OVER SEVERAL LINES.
!+             AIDELU IS USED TO DECODE THE HELP SECTION OF THE
!+             DICTIONARY ONLY, AND THE WORDS IGNORED FOR EDAMOX.
!
!note     PORTABILITY : IBM,CRAY,HP,SUN
!
!warning  FOLLOWS THE FORTRAN CONVENTION : '' IS READ AS
!+            ' WHEN WITHIN A CHARACTER STRING IF THE STRING
!+            IS WRITTEN BETWEEN QUOTES
!+
!warning  QUOTES AT THE BEGINNING AND END OF LINES ARE POSSIBLE
!+            SOURCES OF ERRORS
!
!history  J.M. HERVOUET (LNH); A. YESSAYAN; L. LEGUE
!+        14/01/2008
!+        V5P8
!+   BETTER CONTROL OF 'LONG' LINES
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        13/07/2010
!+        V6P0
!+   Translation of French comments within the FORTRAN sources into
!+   English comments
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        21/08/2010
!+        V6P0
!+   Creation of DOXYGEN tags for automated documentation and
!+   cross-referencing of the FORTRAN sources
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!| DOC            |-->| LOGIQUE DE DOCUMENTATION DE LA SORTIE
!|                |   | = VRAI : IMPRIME L'AIDE (FICHIER RESULTAT)
!|                |   | = FAUX : N'IMPRIME PAS L'AIDE
!| ICOL           |<->| INDICE DU CARACTERE COURANT DANS LA LIGNE
!| LIGNE          |<->| LIGNE EN COURS DE DECODAGE.
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      USE declarations_damocles
      USE declarations_special
      IMPLICIT NONE
!
!
      INTEGER       ICOL
      LOGICAL       DOC
      CHARACTER(LEN=*) LIGNE
!
      INTEGER  NEXT,PRECAR
      EXTERNAL next,precar
!
!-----------------------------------------------------------------------
!
      INTEGER       IDEB,IFIN,JCOL
      CHARACTER(LEN=1)   QUOTE,TABUL,PTVIRG
!
!-----------------------------------------------------------------------
!
      INTRINSIC char
!
!***********************************************************************
!                                   MARKS RCS AND SCCS
!
!***********************************************************************
!
      quote  = ''''
      ptvirg = ';'
      tabul =char(9)
9     icol   = next( icol+1 , ligne )
!
!        //// FINDS THE ENDS OF THE STRING ////
!
!    NOTE: THE STRING CAN BE BETWEEN QUOTES OR NOT.
!          IF NOT, IT CANNOT CONTAIN WHITE CHARACTERS.
!
!
!
      IF ( ligne(icol:icol).NE.quote ) THEN
        ideb = icol
!              PRECAR: SAME FUNCTION AS PREVAL, BUT DOES NOT JUMP
!                      OVER COMMENTED LINES
        icol = precar(icol+1,ligne,' ',ptvirg,tabul) - 1
        ifin = icol
        IF (doc) WRITE(lu,10) ligne(ideb:ifin)
10      FORMAT(1x,a)
      ELSE
!
! IF THE STRING IS BETWEEN QUOTES
!
        ideb = icol + 1
!
! WHILE THERE IS NO QUOTE ON THE LINE
!
100     icol = precar(icol+1,ligne,quote,quote,quote)
        IF (icol.GT.longli) THEN
!         NO QUOTE ON THE LINE, IT'S WRITTEN OUT AND GOES TO NEXT
          IF (doc) WRITE(lu,10) ligne(ideb:longli)
!         READS NEXT LINE
          READ(nfic,end=900,err=998,fmt='(A)') ligne
          nlign = nlign + 1
          icol = 1
          ideb = 1
          GO TO 100
        ELSEIF(icol.EQ.longli) THEN
!       QUOTE AT THE END OF THE LINE, THE LINE IS WRITTEN OUT (EXCEPT
!       THE QUOTE) AND THAT'S IT
          IF (doc) WRITE(lu,10) ligne(ideb:icol-1)
        ELSE
!         NEXT QUOTE
          jcol = precar(icol+1,ligne,quote,quote,quote)
!         IF THERE IS A DOUBLE QUOTE, IT IS DELETED
          IF ((jcol-icol).EQ.1) THEN
            icol=jcol
            ligne(jcol:longli)=ligne(jcol+1:longli) // ' '
            GO TO 100
          ELSE
!           PRINTS OUT THE 'HELP' WHEN DELETING THE LAST QUOTE
            IF (doc) WRITE(lu,10) ligne(ideb:icol-1)
          ENDIF
        ENDIF
      ENDIF
      icol = next(icol+1,ligne)
      IF(icol.LE.longli) THEN
        IF(ligne(icol:icol).EQ.ptvirg(1:1)) GO TO 9
      ENDIF
      GO TO 1000
!
! WRITES OUT ERRORS
!
998   CONTINUE
      WRITE(lu,1999) nfic, nlign
1999  FORMAT(1x,'LOGICAL UNIT ',1i2,'   ERROR ON LINE ',1i6)
900   CONTINUE
      retour = .true.
!
! END OF THE WRITING OF ERRORS
!
1000  CONTINUE
!
! TWO EMPTY LINES FOR THE PAGE LAYOUT
!
      IF (doc) WRITE(lu,*) ' '
      IF (doc) WRITE(lu,*) ' '
!
!-----------------------------------------------------------------------
!
      RETURN
      END