addtracer.f

Go to the documentation of this file.

!                       ********************
                        SUBROUTINE addtracer
!                       ********************
!
     &  (nametrac,mtrac,itrac,add,name1,name2,unit0)
!
!
!***********************************************************************
! BIEF      V7P3
!***********************************************************************
!
!brief    adds tracer to the existing list of tracers
!+
!+        Re-working NAMETRAC to avoid conflicting naming convention
!+        between user defined tracers, water quality processes and
!+        ice processes.
!+        If NAME1 or NAME2 are already in NAMETRAC, then ITRAC takes
!+        the index of that tracer. Otherwise, a new tracer is added to
!+        NAMETRAC and MTRAC is increased by one.
!
!history  S.E. BOURBAN (HRW)
!+        07/06/2017
!+        V7P3
!+        First implementation
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!| ITRAC          |<--| FINAL INDEX OF THE TRACER
!| MTRAC          |<->| TOTAL NUMBER OF TRACERS, COULD VARY HERE
!| NAME1,NAME2    |-->| NAMES IN FRENCH AND ENGLISH OF THE TRACER TO ADD
!| NAMETRAC       |<->| TABLE CONTAINING TRACERS' NAMES
!| UNIT0          |-->| UNIT OF THE TRACER TO ADD
!| ADD            |-->| OPTIONAL: WHETHER TO ADD THE TRACER OR NOT
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      USE declarations_special
      USE bief, ex_addtracer => addtracer
!
      IMPLICIT NONE
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
!
      INTEGER,           INTENT(INOUT):: MTRAC,ITRAC
      CHARACTER(LEN=32), INTENT(INOUT):: NAMETRAC(*)
      CHARACTER(LEN=16), INTENT(IN)   :: NAME1,NAME2,UNIT0
      LOGICAL,           INTENT(IN)   :: ADD
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
!-----------------------------------------------------------------------
      INTEGER :: I
!-----------------------------------------------------------------------
      itrac = 0
      DO i = 1,mtrac
        IF( nametrac(i)(1:16) .EQ. name1 ) THEN
          itrac = i
        ELSEIF( nametrac(i)(1:16) .EQ. name2 ) THEN
          itrac = i
        ENDIF
      ENDDO
      IF( itrac.EQ.0 .AND. add) THEN
        mtrac = mtrac + 1
        itrac = mtrac
        IF(lng.EQ.lng_fr)THEN
          nametrac(itrac) = name1 // unit0
        ELSE
          nametrac(itrac) = name2 // unit0
        ENDIF
      ENDIF
!-----------------------------------------------------------------------
      RETURN
      END SUBROUTINE
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!